pxelinux.asm

   1 ; -*- fundamental -*- (asm-mode sucks)
   2 ; ****************************************************************************
   3 ;
   4 ;  pxelinux.asm
   5 ;
   6 ;  A program to boot Linux kernels off a TFTP server using the Intel PXE
   7 ;  network booting API.  It is based on the SYSLINUX boot loader for
   8 ;  MS-DOS floppies.
   9 ;
  10 ;   Copyright 1994-2008 H. Peter Anvin - All Rights Reserved
  11 ;
  12 ;  This program is free software; you can redistribute it and/or modify
  13 ;  it under the terms of the GNU General Public License as published by
  14 ;  the Free Software Foundation, Inc., 53 Temple Place Ste 330,
  15 ;  Boston MA 02111-1307, USA; either version 2 of the License, or
  16 ;  (at your option) any later version; incorporated herein by reference.
  17 ;
  18 ; ****************************************************************************
  19
  20 %define IS_PXELINUX 1
  21 %include "head.inc"
  22 %include "pxe.inc"
  23
  24 ;
  25 ; Some semi-configurable constants... change on your own risk.
  26 ;
  27 my_id           equ pxelinux_id
  28 FILENAME_MAX_LG2 equ 7                  ; log2(Max filename size Including final null)
  29 FILENAME_MAX    equ (1 << FILENAME_MAX_LG2)
  30 NULLFILE        equ 0                   ; Zero byte == null file name
  31 NULLOFFSET      equ 4                   ; Position in which to look
  32 REBOOT_TIME     equ 5*60                ; If failure, time until full reset
  33 %assign HIGHMEM_SLOP 128*1024           ; Avoid this much memory near the top
  34 MAX_OPEN_LG2    equ 5                   ; log2(Max number of open sockets)
  35 MAX_OPEN        equ (1 << MAX_OPEN_LG2)
  36 PKTBUF_SIZE     equ (65536/MAX_OPEN)    ; Per-socket packet buffer size
  37 TFTP_PORT       equ htons(69)           ; Default TFTP port
  38 PKT_RETRY       equ 6                   ; Packet transmit retry count
  39 PKT_TIMEOUT     equ 12                  ; Initial timeout, timer ticks @ 55 ms
  40 ; Desired TFTP block size
  41 ; For Ethernet MTU is normally 1500.  Unfortunately there seems to
  42 ; be a fair number of networks with "substandard" MTUs which break.
  43 ; The code assumes TFTP_LARGEBLK <= 2K.
  44 TFTP_MTU        equ 1440
  45 TFTP_LARGEBLK   equ (TFTP_MTU-20-8-4)   ; MTU - IP hdr - UDP hdr - TFTP hdr
  46 ; Standard TFTP block size
  47 TFTP_BLOCKSIZE_LG2 equ 9                ; log2(bytes/block)
  48 TFTP_BLOCKSIZE  equ (1 << TFTP_BLOCKSIZE_LG2)
  49 %assign USE_PXE_PROVIDED_STACK 1        ; Use stack provided by PXE?
  50
  51 SECTOR_SHIFT    equ TFTP_BLOCKSIZE_LG2
  52 SECTOR_SIZE     equ TFTP_BLOCKSIZE
  53
  54 ;
  55 ; This is what we need to do when idle
  56 ; *** This is disabled because some PXE stacks wait for unacceptably
  57 ; *** long if there are no packets receivable.
  58
  59 %define HAVE_IDLE 0                     ; idle is not a noop
  60
  61 %if HAVE_IDLE
  62 %macro  RESET_IDLE 0
  63         call reset_idle
  64 %endmacro
  65 %macro  DO_IDLE 0
  66         call check_for_arp
  67 %endmacro
  68 %else
  69 %macro  RESET_IDLE 0
  70         ; Nothing
  71 %endmacro
  72 %macro  DO_IDLE 0
  73         ; Nothing
  74 %endmacro
  75 %endif
  76
  77 ;
  78 ; TFTP operation codes
  79 ;
  80 TFTP_RRQ        equ htons(1)            ; Read request
  81 TFTP_WRQ        equ htons(2)            ; Write request
  82 TFTP_DATA       equ htons(3)            ; Data packet
  83 TFTP_ACK        equ htons(4)            ; ACK packet
  84 TFTP_ERROR      equ htons(5)            ; ERROR packet
  85 TFTP_OACK       equ htons(6)            ; OACK packet
  86
  87 ;
  88 ; TFTP error codes
  89 ;
  90 TFTP_EUNDEF     equ htons(0)            ; Unspecified error
  91 TFTP_ENOTFOUND  equ htons(1)            ; File not found
  92 TFTP_EACCESS    equ htons(2)            ; Access violation
  93 TFTP_ENOSPACE   equ htons(3)            ; Disk full
  94 TFTP_EBADOP     equ htons(4)            ; Invalid TFTP operation
  95 TFTP_EBADID     equ htons(5)            ; Unknown transfer
  96 TFTP_EEXISTS    equ htons(6)            ; File exists
  97 TFTP_ENOUSER    equ htons(7)            ; No such user
  98 TFTP_EOPTNEG    equ htons(8)            ; Option negotiation failure
  99
 100 ;
 101 ; The following structure is used for "virtual kernels"; i.e. LILO-style
 102 ; option labels.  The options we permit here are `kernel' and `append
 103 ; Since there is no room in the bottom 64K for all of these, we
 104 ; stick them in high memory and copy them down before we need them.
 105 ;
 106                 struc vkernel
 107 vk_vname:       resb FILENAME_MAX       ; Virtual name **MUST BE FIRST!**
 108 vk_rname:       resb FILENAME_MAX       ; Real name
 109 vk_ipappend:    resb 1                  ; "IPAPPEND" flag
 110 vk_type:        resb 1                  ; Type of file
 111 vk_appendlen:   resw 1
 112                 alignb 4
 113 vk_append:      resb max_cmd_len+1      ; Command line
 114                 alignb 4
 115 vk_end:         equ $                   ; Should be <= vk_size
 116                 endstruc
 117
 118 ;
 119 ; Segment assignments in the bottom 640K
 120 ; 0000h - main code/data segment (and BIOS segment)
 121 ;
 122 real_mode_seg   equ 3000h
 123 pktbuf_seg      equ 2000h               ; Packet buffers segments
 124 xfer_buf_seg    equ 1000h               ; Bounce buffer for I/O to high mem
 125 comboot_seg     equ real_mode_seg       ; COMBOOT image loading zone
 126
 127 ;
 128 ; BOOTP/DHCP packet pattern
 129 ;
 130                 struc bootp_t
 131 bootp:
 132 .opcode         resb 1                  ; BOOTP/DHCP "opcode"
 133 .hardware       resb 1                  ; ARP hardware type
 134 .hardlen        resb 1                  ; Hardware address length
 135 .gatehops       resb 1                  ; Used by forwarders
 136 .ident          resd 1                  ; Transaction ID
 137 .seconds        resw 1                  ; Seconds elapsed
 138 .flags          resw 1                  ; Broadcast flags
 139 .cip            resd 1                  ; Client IP
 140 .yip            resd 1                  ; "Your" IP
 141 .sip            resd 1                  ; Next server IP
 142 .gip            resd 1                  ; Relay agent IP
 143 .macaddr        resb 16                 ; Client MAC address
 144 .sname          resb 64                 ; Server name (optional)
 145 .bootfile       resb 128                ; Boot file name
 146 .option_magic   resd 1                  ; Vendor option magic cookie
 147 .options        resb 1260               ; Vendor options
 148                 endstruc
 149
 150 BOOTP_OPTION_MAGIC      equ htonl(0x63825363)   ; See RFC 2132
 151
 152 ;
 153 ; TFTP connection data structure.  Each one of these corresponds to a local
 154 ; UDP port.  The size of this structure must be a power of 2.
 155 ; HBO = host byte order; NBO = network byte order
 156 ; (*) = written by options negotiation code, must be dword sized
 157 ;
 158                 struc open_file_t
 159 tftp_localport  resw 1                  ; Local port number     (0 = not in use)
 160 tftp_remoteport resw 1                  ; Remote port number
 161 tftp_remoteip   resd 1                  ; Remote IP address
 162 tftp_filepos    resd 1                  ; Bytes downloaded (including buffer)
 163 tftp_filesize   resd 1                  ; Total file size(*)
 164 tftp_blksize    resd 1                  ; Block size for this connection(*)
 165 tftp_bytesleft  resw 1                  ; Unclaimed data bytes
 166 tftp_lastpkt    resw 1                  ; Sequence number of last packet (NBO)
 167 tftp_dataptr    resw 1                  ; Pointer to available data
 168 tftp_goteof     resb 1                  ; 1 if the EOF packet received
 169                 resb 3                  ; Currently unusued
 170                 ; At end since it should not be zeroed on socked close
 171 tftp_pktbuf     resw 1                  ; Packet buffer offset
 172                 endstruc
 173 %ifndef DEPEND
 174 %if (open_file_t_size & (open_file_t_size-1))
 175 %error "open_file_t is not a power of 2"
 176 %endif
 177 %endif
 178
 179 ; ---------------------------------------------------------------------------
 180 ;   BEGIN CODE
 181 ; ---------------------------------------------------------------------------
 182
 183 ;
 184 ; Memory below this point is reserved for the BIOS and the MBR
 185 ;
 186                 section .earlybss
 187 trackbufsize    equ 8192
 188 trackbuf        resb trackbufsize       ; Track buffer goes here
 189                 ; ends at 2800h
 190
 191                 alignb open_file_t_size
 192 Files           resb MAX_OPEN*open_file_t_size
 193
 194                 alignb FILENAME_MAX
 195 BootFile        resb 256                ; Boot file from DHCP packet
 196 PathPrefix      resb 256                ; Path prefix derived from boot file
 197 DotQuadBuf      resb 16                 ; Buffer for dotted-quad IP address
 198 IPOption        resb 80                 ; ip= option buffer
 199 InitStack       resd 1                  ; Pointer to reset stack (SS:SP)
 200 PXEStack        resd 1                  ; Saved stack during PXE call
 201
 202                 section .bss
 203                 alignb 4
 204 RebootTime      resd 1                  ; Reboot timeout, if set by option
 205 StrucPtr        resd 1                  ; Pointer to PXENV+ or !PXE structure
 206 APIVer          resw 1                  ; PXE API version found
 207 IPOptionLen     resw 1                  ; Length of IPOption
 208 IdleTimer       resw 1                  ; Time to check for ARP?
 209 LocalBootType   resw 1                  ; Local boot return code
 210 PktTimeout      resw 1                  ; Timeout for current packet
 211 RealBaseMem     resw 1                  ; Amount of DOS memory after freeing
 212 OverLoad        resb 1                  ; Set if DHCP packet uses "overloading"
 213 DHCPMagic       resb 1                  ; PXELINUX magic flags
 214
 215 ; The relative position of these fields matter!
 216 MAC_MAX         equ  32                 ; Handle hardware addresses this long
 217 MACLen          resb 1                  ; MAC address len
 218 MACType         resb 1                  ; MAC address type
 219 MAC             resb MAC_MAX+1          ; Actual MAC address
 220 BOOTIFStr       resb 7                  ; Space for "BOOTIF="
 221 MACStr          resb 3*(MAC_MAX+1)      ; MAC address as a string
 222
 223 ; The relative position of these fields matter!
 224 UUIDType        resb 1                  ; Type byte from DHCP option
 225 UUID            resb 16                 ; UUID, from the PXE stack
 226 UUIDNull        resb 1                  ; dhcp_copyoption zero-terminates
 227
 228 ;
 229 ; PXE packets which don't need static initialization
 230 ;
 231                 alignb 4
 232 pxe_unload_stack_pkt:
 233 .status:        resw 1                  ; Status
 234 .reserved:      resw 10                 ; Reserved
 235 pxe_unload_stack_pkt_len        equ $-pxe_unload_stack_pkt
 236
 237                 alignb 16
 238                 ; BOOTP/DHCP packet buffer
 239
 240                 section .bss2
 241                 alignb 16
 242 packet_buf      resb 2048               ; Transfer packet
 243 packet_buf_size equ $-packet_buf
 244
 245                 section .text
 246                 ;
 247                 ; PXELINUX needs more BSS than the other derivatives;
 248                 ; therefore we relocate it from 7C00h on startup.
 249                 ;
 250 StackBuf        equ $                   ; Base of stack if we use our own
 251
 252 ;
 253 ; Primary entry point.
 254 ;
 255 bootsec         equ $
 256 _start:
 257                 pushfd                  ; Paranoia... in case of return to PXE
 258                 pushad                  ; ... save as much state as possible
 259                 push ds
 260                 push es
 261                 push fs
 262                 push gs
 263
 264                 xor ax,ax
 265                 mov ds,ax
 266                 mov es,ax
 267
 268 %ifndef DEPEND
 269 %if TEXT_START != 0x7c00
 270                 ; This is uglier than it should be, but works around
 271                 ; some NASM 0.98.38 bugs.
 272                 mov di,section..bcopy32.start
 273                 add di,__bcopy_size-4
 274                 lea si,[di-(TEXT_START-7C00h)]
 275                 lea cx,[di-(TEXT_START-4)]
 276                 shr cx,2
 277                 std                     ; Overlapping areas, copy backwards
 278                 rep movsd
 279 %endif
 280 %endif
 281                 jmp 0:_start1           ; Canonicalize address
 282 _start1:
 283                 mov bp,sp
 284                 les bx,[bp+48]          ; ES:BX -> !PXE or PXENV+ structure
 285
 286                 ; That is all pushed onto the PXE stack.  Save the pointer
 287                 ; to it and switch to an internal stack.
 288                 mov [InitStack],sp
 289                 mov [InitStack+2],ss
 290
 291 %if USE_PXE_PROVIDED_STACK
 292                 ; Apparently some platforms go bonkers if we
 293                 ; set up our own stack...
 294                 mov [BaseStack],sp
 295                 mov [BaseStack+4],ss
 296 %endif
 297
 298                 cli                     ; Paranoia
 299                 lss esp,[BaseStack]
 300
 301                 sti                     ; Stack set up and ready
 302                 cld                     ; Copy upwards
 303
 304 ;
 305 ; Initialize screen (if we're using one)
 306 ;
 307                 push es                 ; Save ES -> PXE entry structure
 308                 push ds
 309                 pop es                  ; ES <- DS
 310 %include "init.inc"
 311                 pop es                  ; Restore ES -> PXE entry structure
 312 ;
 313 ; Tell the user we got this far
 314 ;
 315                 mov si,syslinux_banner
 316                 call writestr
 317
 318                 mov si,copyright_str
 319                 call writestr
 320
 321 ;
 322 ; Assume API version 2.1, in case we find the !PXE structure without
 323 ; finding the PXENV+ structure.  This should really look at the Base
 324 ; Code ROM ID structure in have_pxe, but this is adequate for now --
 325 ; if we have !PXE, we have to be 2.1 or higher, and we don't care
 326 ; about higher versions than that.
 327 ;
 328                 mov word [APIVer],0201h
 329
 330 ;
 331 ; Now we need to find the !PXE structure.  It's *supposed* to be pointed
 332 ; to by SS:[SP+4], but support INT 1Ah, AX=5650h method as well.
 333 ; FIX: ES:BX should point to the PXENV+ structure on entry as well.
 334 ; We should make that the second test, and not trash ES:BX...
 335 ;
 336                 cmp dword [es:bx], '!PXE'
 337                 je have_pxe
 338
 339                 ; Uh-oh, not there... try plan B
 340                 mov ax, 5650h
 341 %if USE_PXE_PROVIDED_STACK == 0
 342                 lss sp,[InitStack]
 343 %endif
 344                 int 1Ah                                 ; May trash regs
 345 %if USE_PXE_PROVIDED_STACK == 0
 346                 lss esp,[BaseStack]
 347 %endif
 348
 349                 jc no_pxe
 350                 cmp ax,564Eh
 351                 jne no_pxe
 352
 353                 ; Okay, that gave us the PXENV+ structure, find !PXE
 354                 ; structure from that (if available)
 355                 cmp dword [es:bx], 'PXEN'
 356                 jne no_pxe
 357                 cmp word [es:bx+4], 'V+'
 358                 je have_pxenv
 359
 360                 ; Nothing there either.  Last-ditch: scan memory
 361                 call memory_scan_for_pxe_struct         ; !PXE scan
 362                 jnc have_pxe
 363                 call memory_scan_for_pxenv_struct       ; PXENV+ scan
 364                 jnc have_pxenv
 365
 366 no_pxe:         mov si,err_nopxe
 367                 call writestr
 368                 jmp kaboom
 369
 370 have_pxenv:
 371                 mov [StrucPtr],bx
 372                 mov [StrucPtr+2],es
 373
 374                 mov si,found_pxenv
 375                 call writestr
 376
 377                 mov si,apiver_str
 378                 call writestr
 379                 mov ax,[es:bx+6]
 380                 mov [APIVer],ax
 381                 call writehex4
 382                 call crlf
 383
 384                 cmp ax,0201h                    ; API version 2.1 or higher
 385                 jb old_api
 386                 mov si,bx
 387                 mov ax,es
 388                 les bx,[es:bx+28h]              ; !PXE structure pointer
 389                 cmp dword [es:bx],'!PXE'
 390                 je have_pxe
 391
 392                 ; Nope, !PXE structure missing despite API 2.1+, or at least
 393                 ; the pointer is missing.  Do a last-ditch attempt to find it.
 394                 call memory_scan_for_pxe_struct
 395                 jnc have_pxe
 396
 397                 ; Otherwise, no dice, use PXENV+ structure
 398                 mov bx,si
 399                 mov es,ax
 400
 401 old_api:        ; Need to use a PXENV+ structure
 402                 mov si,using_pxenv_msg
 403                 call writestr
 404
 405                 mov eax,[es:bx+0Ah]             ; PXE RM API
 406                 mov [PXENVEntry],eax
 407
 408                 mov si,undi_data_msg
 409                 call writestr
 410                 mov ax,[es:bx+20h]
 411                 call writehex4
 412                 call crlf
 413                 mov si,undi_data_len_msg
 414                 call writestr
 415                 mov ax,[es:bx+22h]
 416                 call writehex4
 417                 call crlf
 418                 mov si,undi_code_msg
 419                 call writestr
 420                 mov ax,[es:bx+24h]
 421                 call writehex4
 422                 call crlf
 423                 mov si,undi_code_len_msg
 424                 call writestr
 425                 mov ax,[es:bx+26h]
 426                 call writehex4
 427                 call crlf
 428
 429                 ; Compute base memory size from PXENV+ structure
 430                 xor esi,esi
 431                 movzx eax,word [es:bx+20h]      ; UNDI data seg
 432                 cmp ax,[es:bx+24h]              ; UNDI code seg
 433                 ja .use_data
 434                 mov ax,[es:bx+24h]
 435                 mov si,[es:bx+26h]
 436                 jmp short .combine
 437 .use_data:
 438                 mov si,[es:bx+22h]
 439 .combine:
 440                 shl eax,4
 441                 add eax,esi
 442                 shr eax,10                      ; Convert to kilobytes
 443                 mov [RealBaseMem],ax
 444
 445                 mov si,pxenventry_msg
 446                 call writestr
 447                 mov ax,[PXENVEntry+2]
 448                 call writehex4
 449                 mov al,':'
 450                 call writechr
 451                 mov ax,[PXENVEntry]
 452                 call writehex4
 453                 call crlf
 454                 jmp have_entrypoint
 455
 456 have_pxe:
 457                 mov [StrucPtr],bx
 458                 mov [StrucPtr+2],es
 459
 460                 mov eax,[es:bx+10h]
 461                 mov [PXEEntry],eax
 462
 463                 mov si,undi_data_msg
 464                 call writestr
 465                 mov eax,[es:bx+2Ah]
 466                 call writehex8
 467                 call crlf
 468                 mov si,undi_data_len_msg
 469                 call writestr
 470                 mov ax,[es:bx+2Eh]
 471                 call writehex4
 472                 call crlf
 473                 mov si,undi_code_msg
 474                 call writestr
 475                 mov ax,[es:bx+32h]
 476                 call writehex8
 477                 call crlf
 478                 mov si,undi_code_len_msg
 479                 call writestr
 480                 mov ax,[es:bx+36h]
 481                 call writehex4
 482                 call crlf
 483
 484                 ; Compute base memory size from !PXE structure
 485                 xor esi,esi
 486                 mov eax,[es:bx+2Ah]
 487                 cmp eax,[es:bx+32h]
 488                 ja .use_data
 489                 mov eax,[es:bx+32h]
 490                 mov si,[es:bx+36h]
 491                 jmp short .combine
 492 .use_data:
 493                 mov si,[es:bx+2Eh]
 494 .combine:
 495                 add eax,esi
 496                 shr eax,10
 497                 mov [RealBaseMem],ax
 498
 499                 mov si,pxeentry_msg
 500                 call writestr
 501                 mov ax,[PXEEntry+2]
 502                 call writehex4
 503                 mov al,':'
 504                 call writechr
 505                 mov ax,[PXEEntry]
 506                 call writehex4
 507                 call crlf
 508
 509 have_entrypoint:
 510                 push cs
 511                 pop es                          ; Restore CS == DS == ES
 512
 513 ;
 514 ; Network-specific initialization
 515 ;
 516                 xor ax,ax
 517                 mov [LocalDomain],al            ; No LocalDomain received
 518
 519 ;
 520 ; The DHCP client identifiers are best gotten from the DHCPREQUEST
 521 ; packet (query info 1).
 522 ;
 523 query_bootp_1:
 524                 mov dl,1
 525                 call pxe_get_cached_info
 526                 call parse_dhcp
 527
 528                 ; We don't use flags from the request packet, so
 529                 ; this is a good time to initialize DHCPMagic...
 530                 ; Initialize it to 1 meaning we will accept options found;
 531                 ; in earlier versions of PXELINUX bit 0 was used to indicate
 532                 ; we have found option 208 with the appropriate magic number;
 533                 ; we no longer require that, but MAY want to re-introduce
 534                 ; it in the future for vendor encapsulated options.
 535                 mov byte [DHCPMagic],1
 536
 537 ;
 538 ; Now attempt to get the BOOTP/DHCP packet that brought us life (and an IP
 539 ; address).  This lives in the DHCPACK packet (query info 2).
 540 ;
 541 query_bootp_2:
 542                 mov dl,2
 543                 call pxe_get_cached_info
 544                 call parse_dhcp                 ; Parse DHCP packet
 545 ;
 546 ; Save away MAC address (assume this is in query info 2.  If this
 547 ; turns out to be problematic it might be better getting it from
 548 ; the query info 1 packet.)
 549 ;
 550 .save_mac:
 551                 movzx cx,byte [trackbuf+bootp.hardlen]
 552                 cmp cx,16
 553                 jna .mac_ok
 554                 xor cx,cx               ; Bad hardware address length
 555 .mac_ok:
 556                 mov [MACLen],cl
 557                 mov al,[trackbuf+bootp.hardware]
 558                 mov [MACType],al
 559                 mov si,trackbuf+bootp.macaddr
 560                 mov di,MAC
 561                 rep movsb
 562
 563 ; Enable this if we really need to zero-pad this field...
 564 ;               mov cx,MAC+MAC_MAX+1
 565 ;               sub cx,di
 566 ;               xor ax,ax
 567 ;               rep stosb
 568
 569 ;
 570 ; Now, get the boot file and other info.  This lives in the CACHED_REPLY
 571 ; packet (query info 3).
 572 ;
 573                 mov dl,3
 574                 call pxe_get_cached_info
 575                 call parse_dhcp                 ; Parse DHCP packet
 576
 577 ;
 578 ; Generate the bootif string, and the hardware-based config string.
 579 ;
 580 make_bootif_string:
 581                 mov si,bootif_str
 582                 mov di,BOOTIFStr
 583                 mov cx,bootif_str_len
 584                 rep movsb
 585
 586                 movzx cx,byte [MACLen]
 587                 mov si,MACType
 588                 inc cx
 589 .hexify_mac:
 590                 push cx
 591                 mov cl,1                ; CH == 0 already
 592                 call lchexbytes
 593                 mov al,'-'
 594                 stosb
 595                 pop cx
 596                 loop .hexify_mac
 597                 mov [di-1],cl           ; Null-terminate and strip final dash
 598 ;
 599 ; Generate ip= option
 600 ;
 601                 call genipopt
 602
 603 ;
 604 ; Print IP address
 605 ;
 606                 mov eax,[MyIP]
 607                 mov di,DotQuadBuf
 608                 push di
 609                 call gendotquad                 ; This takes network byte order input
 610
 611                 xchg ah,al                      ; Convert to host byte order
 612                 ror eax,16                      ; (BSWAP doesn't work on 386)
 613                 xchg ah,al
 614
 615                 mov si,myipaddr_msg
 616                 call writestr
 617                 call writehex8
 618                 mov al,' '
 619                 call writechr
 620                 pop si                          ; DotQuadBuf
 621                 call writestr
 622                 call crlf
 623
 624                 mov si,IPOption
 625                 call writestr
 626                 call crlf
 627
 628 ;
 629 ; Check to see if we got any PXELINUX-specific DHCP options; in particular,
 630 ; if we didn't get the magic enable, do not recognize any other options.
 631 ;
 632 check_dhcp_magic:
 633                 test byte [DHCPMagic], 1        ; If we didn't get the magic enable...
 634                 jnz .got_magic
 635                 mov byte [DHCPMagic], 0         ; If not, kill all other options
 636 .got_magic:
 637
 638
 639 ;
 640 ; Initialize UDP stack
 641 ;
 642 udp_init:
 643                 mov eax,[MyIP]
 644                 mov [pxe_udp_open_pkt.sip],eax
 645                 mov di,pxe_udp_open_pkt
 646                 mov bx,PXENV_UDP_OPEN
 647                 call pxenv
 648                 jc .failed
 649                 cmp word [pxe_udp_open_pkt.status], byte 0
 650                 je .success
 651 .failed:        mov si,err_udpinit
 652                 call writestr
 653                 jmp kaboom
 654 .success:
 655
 656 ;
 657 ; Common initialization code
 658 ;
 659 %include "cpuinit.inc"
 660
 661 ;
 662 ; Now we're all set to start with our *real* business.  First load the
 663 ; configuration file (if any) and parse it.
 664 ;
 665 ; In previous versions I avoided using 32-bit registers because of a
 666 ; rumour some BIOSes clobbered the upper half of 32-bit registers at
 667 ; random.  I figure, though, that if there are any of those still left
 668 ; they probably won't be trying to install Linux on them...
 669 ;
 670 ; The code is still ripe with 16-bitisms, though.  Not worth the hassle
 671 ; to take'm out.  In fact, we may want to put them back if we're going
 672 ; to boot ELKS at some point.
 673 ;
 674
 675 ;
 676 ; Store standard filename prefix
 677 ;
 678 prefix:         test byte [DHCPMagic], 04h      ; Did we get a path prefix option
 679                 jnz .got_prefix
 680                 mov si,BootFile
 681                 mov di,PathPrefix
 682                 cld
 683                 call strcpy
 684                 mov cx,di
 685                 sub cx,PathPrefix+1
 686                 std
 687                 lea si,[di-2]                   ; Skip final null!
 688 .find_alnum:    lodsb
 689                 or al,20h
 690                 cmp al,'.'                      ; Count . or - as alphanum
 691                 je .alnum
 692                 cmp al,'-'
 693                 je .alnum
 694                 cmp al,'0'
 695                 jb .notalnum
 696                 cmp al,'9'
 697                 jbe .alnum
 698                 cmp al,'a'
 699                 jb .notalnum
 700                 cmp al,'z'
 701                 ja .notalnum
 702 .alnum:         loop .find_alnum
 703                 dec si
 704 .notalnum:      mov byte [si+2],0               ; Zero-terminate after delimiter
 705                 cld
 706 .got_prefix:
 707                 mov si,tftpprefix_msg
 708                 call writestr
 709                 mov si,PathPrefix
 710                 call writestr
 711                 call crlf
 712
 713 ;
 714 ; Load configuration file
 715 ;
 716 find_config:
 717
 718 ;
 719 ; Begin looking for configuration file
 720 ;
 721 config_scan:
 722                 test byte [DHCPMagic], 02h
 723                 jz .no_option
 724
 725                 ; We got a DHCP option, try it first
 726                 call .try
 727                 jnz .success
 728
 729 .no_option:
 730                 mov di,ConfigName
 731                 mov si,cfgprefix
 732                 mov cx,cfgprefix_len
 733                 rep movsb
 734
 735                 ; Have to guess config file name...
 736
 737                 ; Try loading by UUID.
 738                 cmp byte [HaveUUID],0
 739                 je .no_uuid
 740
 741                 push di
 742                 mov bx,uuid_dashes
 743                 mov si,UUID
 744 .gen_uuid:
 745                 movzx cx,byte [bx]
 746                 jcxz .done_uuid
 747                 inc bx
 748                 call lchexbytes
 749                 mov al,'-'
 750                 stosb
 751                 jmp .gen_uuid
 752 .done_uuid:
 753                 mov [di-1],cl           ; Remove last dash and zero-terminate
 754                 pop di
 755                 call .try
 756                 jnz .success
 757 .no_uuid:
 758
 759                 ; Try loading by MAC address
 760                 push di
 761                 mov si,MACStr
 762                 call strcpy
 763                 pop di
 764                 call .try
 765                 jnz .success
 766
 767                 ; Nope, try hexadecimal IP prefixes...
 768 .scan_ip:
 769                 mov cx,4
 770                 mov si,MyIP
 771                 call uchexbytes                 ; Convert to hex string
 772
 773                 mov cx,8                        ; Up to 8 attempts
 774 .tryagain:
 775                 mov byte [di],0                 ; Zero-terminate string
 776                 call .try
 777                 jnz .success
 778                 dec di                          ; Drop one character
 779                 loop .tryagain
 780
 781                 ; Final attempt: "default" string
 782                 mov si,default_str              ; "default" string
 783                 call strcpy
 784                 call .try
 785                 jnz .success
 786
 787                 mov si,err_noconfig
 788                 call writestr
 789                 jmp kaboom
 790
 791 .try:
 792                 pusha
 793                 mov si,trying_msg
 794                 call writestr
 795                 mov di,ConfigName
 796                 mov si,di
 797                 call writestr
 798                 call crlf
 799                 mov si,di
 800                 mov di,KernelName       ;  Borrow this buffer for mangled name
 801                 call mangle_name
 802                 call open
 803                 popa
 804                 ret
 805
 806
 807 .success:
 808
 809 ;
 810 ; Linux kernel loading code is common.  However, we need to define
 811 ; a couple of helper macros...
 812 ;
 813
 814 ; Handle "ipappend" option
 815 %define HAVE_SPECIAL_APPEND
 816 %macro  SPECIAL_APPEND 0
 817                 test byte [IPAppend],01h        ; ip=
 818                 jz .noipappend1
 819                 mov si,IPOption
 820                 mov cx,[IPOptionLen]
 821                 rep movsb
 822                 mov al,' '
 823                 stosb
 824 .noipappend1:
 825                 test byte [IPAppend],02h
 826                 jz .noipappend2
 827                 mov si,BOOTIFStr
 828                 call strcpy
 829                 mov byte [es:di-1],' '          ; Replace null with space
 830 .noipappend2:
 831 %endmacro
 832
 833 ; Unload PXE stack
 834 %define HAVE_UNLOAD_PREP
 835 %macro  UNLOAD_PREP 0
 836                 call unload_pxe
 837 %endmacro
 838
 839 ;
 840 ; Now we have the config file open.  Parse the config file and
 841 ; run the user interface.
 842 ;
 843 %include "ui.inc"
 844
 845 ;
 846 ; Boot to the local disk by returning the appropriate PXE magic.
 847 ; AX contains the appropriate return code.
 848 ;
 849 local_boot:
 850                 push cs
 851                 pop ds
 852                 mov [LocalBootType],ax
 853                 call vgaclearmode
 854                 mov si,localboot_msg
 855                 call writestr
 856                 ; Restore the environment we were called with
 857                 lss sp,[InitStack]
 858                 pop gs
 859                 pop fs
 860                 pop es
 861                 pop ds
 862                 popad
 863                 mov ax,[cs:LocalBootType]
 864                 popfd
 865                 retf                            ; Return to PXE
 866
 867 ;
 868 ; kaboom: write a message and bail out.  Wait for quite a while,
 869 ;         or a user keypress, then do a hard reboot.
 870 ;
 871 kaboom:
 872                 RESET_STACK_AND_SEGS AX
 873 .patch:         mov si,bailmsg
 874                 call writestr           ; Returns with AL = 0
 875 .drain:         call pollchar
 876                 jz .drained
 877                 call getchar
 878                 jmp short .drain
 879 .drained:
 880                 mov edi,[RebootTime]
 881                 mov al,[DHCPMagic]
 882                 and al,09h              ; Magic+Timeout
 883                 cmp al,09h
 884                 je .time_set
 885                 mov edi,REBOOT_TIME
 886 .time_set:
 887                 mov cx,18
 888 .wait1:         push cx
 889                 mov ecx,edi
 890 .wait2:         mov dx,[BIOS_timer]
 891 .wait3:         call pollchar
 892                 jnz .keypress
 893                 cmp dx,[BIOS_timer]
 894                 je .wait3
 895                 loop .wait2,ecx
 896                 mov al,'.'
 897                 call writechr
 898                 pop cx
 899                 loop .wait1
 900 .keypress:
 901                 call crlf
 902                 mov word [BIOS_magic],0 ; Cold reboot
 903                 jmp 0F000h:0FFF0h       ; Reset vector address
 904
 905 ;
 906 ; memory_scan_for_pxe_struct:
 907 ;
 908 ;       If none of the standard methods find the !PXE structure, look for it
 909 ;       by scanning memory.
 910 ;
 911 ;       On exit, if found:
 912 ;               CF = 0, ES:BX -> !PXE structure
 913 ;       Otherwise CF = 1, all registers saved
 914 ;
 915 memory_scan_for_pxe_struct:
 916                 push ds
 917                 pusha
 918                 mov ax,cs
 919                 mov ds,ax
 920                 mov si,trymempxe_msg
 921                 call writestr
 922                 mov ax,[BIOS_fbm]       ; Starting segment
 923                 shl ax,(10-4)           ; Kilobytes -> paragraphs
 924 ;               mov ax,01000h           ; Start to look here
 925                 dec ax                  ; To skip inc ax
 926 .mismatch:
 927                 inc ax
 928                 cmp ax,0A000h           ; End of memory
 929                 jae .not_found
 930                 call writehex4
 931                 mov si,fourbs_msg
 932                 call writestr
 933                 mov es,ax
 934                 mov edx,[es:0]
 935                 cmp edx,'!PXE'
 936                 jne .mismatch
 937                 movzx cx,byte [es:4]    ; Length of structure
 938                 cmp cl,08h              ; Minimum length
 939                 jb .mismatch
 940                 push ax
 941                 xor ax,ax
 942                 xor si,si
 943 .checksum:      es lodsb
 944                 add ah,al
 945                 loop .checksum
 946                 pop ax
 947                 jnz .mismatch           ; Checksum must == 0
 948 .found:         mov bp,sp
 949                 xor bx,bx
 950                 mov [bp+8],bx           ; Save BX into stack frame (will be == 0)
 951                 mov ax,es
 952                 call writehex4
 953                 call crlf
 954                 popa
 955                 pop ds
 956                 clc
 957                 ret
 958 .not_found:     mov si,notfound_msg
 959                 call writestr
 960                 popa
 961                 pop ds
 962                 stc
 963                 ret
 964
 965 ;
 966 ; memory_scan_for_pxenv_struct:
 967 ;
 968 ;       If none of the standard methods find the PXENV+ structure, look for it
 969 ;       by scanning memory.
 970 ;
 971 ;       On exit, if found:
 972 ;               CF = 0, ES:BX -> PXENV+ structure
 973 ;       Otherwise CF = 1, all registers saved
 974 ;
 975 memory_scan_for_pxenv_struct:
 976                 pusha
 977                 mov si,trymempxenv_msg
 978                 call writestr
 979 ;               mov ax,[BIOS_fbm]       ; Starting segment
 980 ;               shl ax,(10-4)           ; Kilobytes -> paragraphs
 981                 mov ax,01000h           ; Start to look here
 982                 dec ax                  ; To skip inc ax
 983 .mismatch:
 984                 inc ax
 985                 cmp ax,0A000h           ; End of memory
 986                 jae .not_found
 987                 mov es,ax
 988                 mov edx,[es:0]
 989                 cmp edx,'PXEN'
 990                 jne .mismatch
 991                 mov dx,[es:4]
 992                 cmp dx,'V+'
 993                 jne .mismatch
 994                 movzx cx,byte [es:8]    ; Length of structure
 995                 cmp cl,26h              ; Minimum length
 996                 jb .mismatch
 997                 xor ax,ax
 998                 xor si,si
 999 .checksum:      es lodsb
1000                 add ah,al
1001                 loop .checksum
1002                 and ah,ah
1003                 jnz .mismatch           ; Checksum must == 0
1004 .found:         mov bp,sp
1005                 mov [bp+8],bx           ; Save BX into stack frame
1006                 mov ax,bx
1007                 call writehex4
1008                 call crlf
1009                 clc
1010                 ret
1011 .not_found:     mov si,notfound_msg
1012                 call writestr
1013                 popad
1014                 stc
1015                 ret
1016
1017 ;
1018 ; close_file:
1019 ;            Deallocates a file structure (pointer in SI)
1020 ;            Assumes CS == DS.
1021 ;
1022 ; XXX: We should check to see if this file is still open on the server
1023 ; side and send a courtesy ERROR packet to the server.
1024 ;
1025 close_file:
1026                 and si,si
1027                 jz .closed
1028                 mov word [si],0         ; Not in use
1029 .closed:        ret
1030
1031 ;
1032 ; searchdir:
1033 ;
1034 ;       Open a TFTP connection to the server
1035 ;
1036 ;            On entry:
1037 ;               DS:DI   = mangled filename
1038 ;            If successful:
1039 ;               ZF clear
1040 ;               SI      = socket pointer
1041 ;               EAX     = file length in bytes, or -1 if unknown
1042 ;            If unsuccessful
1043 ;               ZF set
1044 ;
1045
1046 searchdir:
1047                 push es
1048                 push bx
1049                 push cx
1050                 mov ax,ds
1051                 mov es,ax
1052                 mov si,di
1053                 push bp
1054                 mov bp,sp
1055
1056                 call allocate_socket
1057                 jz .ret
1058
1059                 mov ax,PKT_RETRY        ; Retry counter
1060                 mov word [PktTimeout],PKT_TIMEOUT       ; Initial timeout
1061
1062 .sendreq:       push ax                 ; [bp-2]  - Retry counter
1063                 push si                 ; [bp-4]  - File name
1064
1065                 mov di,packet_buf
1066                 mov [pxe_udp_write_pkt.buffer],di
1067
1068                 mov ax,TFTP_RRQ         ; TFTP opcode
1069                 stosw
1070
1071                 lodsd                   ; EAX <- server override (if any)
1072                 and eax,eax
1073                 jnz .noprefix           ; No prefix, and we have the server
1074
1075                 push si                 ; Add common prefix
1076                 mov si,PathPrefix
1077                 call strcpy
1078                 dec di
1079                 pop si
1080
1081                 mov eax,[ServerIP]      ; Get default server
1082
1083 .noprefix:
1084                 call strcpy             ; Filename
1085
1086                 mov [bx+tftp_remoteip],eax
1087
1088                 push bx                 ; [bp-6]  - TFTP block
1089                 mov bx,[bx]
1090                 push bx                 ; [bp-8]  - TID (local port no)
1091
1092                 mov [pxe_udp_write_pkt.status],byte 0
1093                 mov [pxe_udp_write_pkt.sip],eax
1094                 ; Now figure out the gateway
1095                 xor eax,[MyIP]
1096                 and eax,[Netmask]
1097                 jz .nogwneeded
1098                 mov eax,[Gateway]
1099 .nogwneeded:
1100                 mov [pxe_udp_write_pkt.gip],eax
1101                 mov [pxe_udp_write_pkt.lport],bx
1102                 mov ax,[ServerPort]
1103                 mov [pxe_udp_write_pkt.rport],ax
1104                 mov si,tftp_tail
1105                 mov cx,tftp_tail_len
1106                 rep movsb
1107                 sub di,packet_buf       ; Get packet size
1108                 mov [pxe_udp_write_pkt.buffersize],di
1109
1110                 mov di,pxe_udp_write_pkt
1111                 mov bx,PXENV_UDP_WRITE
1112                 call pxenv
1113                 jc .failure
1114                 cmp word [pxe_udp_write_pkt.status],byte 0
1115                 jne .failure
1116
1117                 ;
1118                 ; Danger, Will Robinson!  We need to support timeout
1119                 ; and retry lest we just lost a packet...
1120                 ;
1121
1122                 ; Packet transmitted OK, now we need to receive
1123 .getpacket:     push word [PktTimeout]  ; [bp-10]
1124                 push word [BIOS_timer]  ; [bp-12]
1125
1126 .pkt_loop:      mov bx,[bp-8]           ; TID
1127                 mov di,packet_buf
1128                 mov word [pxe_udp_read_pkt.status],0
1129                 mov [pxe_udp_read_pkt.buffer],di
1130                 mov [pxe_udp_read_pkt.buffer+2],ds
1131                 mov word [pxe_udp_read_pkt.buffersize],packet_buf_size
1132                 mov eax,[MyIP]
1133                 mov [pxe_udp_read_pkt.dip],eax
1134                 mov [pxe_udp_read_pkt.lport],bx
1135                 mov di,pxe_udp_read_pkt
1136                 mov bx,PXENV_UDP_READ
1137                 call pxenv
1138                 and ax,ax
1139                 jz .got_packet                  ; Wait for packet
1140 .no_packet:
1141                 mov dx,[BIOS_timer]
1142                 cmp dx,[bp-12]
1143                 je .pkt_loop
1144                 mov [bp-12],dx
1145                 dec word [bp-10]                ; Timeout
1146                 jnz .pkt_loop
1147                 pop ax  ; Adjust stack
1148                 pop ax
1149                 shl word [PktTimeout],1         ; Exponential backoff
1150                 jmp .failure
1151
1152 .got_packet:
1153                 mov si,[bp-6]                   ; TFTP pointer
1154                 mov bx,[bp-8]                   ; TID
1155
1156                 ; Make sure the packet actually came from the server
1157                 ; This is technically not to the TFTP spec?
1158                 mov eax,[si+tftp_remoteip]
1159                 cmp [pxe_udp_read_pkt.sip],eax
1160                 jne .no_packet
1161
1162                 ; Got packet - reset timeout
1163                 mov word [PktTimeout],PKT_TIMEOUT
1164
1165                 pop ax  ; Adjust stack
1166                 pop ax
1167
1168                 mov ax,[pxe_udp_read_pkt.rport]
1169                 mov [si+tftp_remoteport],ax
1170
1171                 ; filesize <- -1 == unknown
1172                 mov dword [si+tftp_filesize], -1
1173                 ; Default blksize unless blksize option negotiated
1174                 mov word [si+tftp_blksize], TFTP_BLOCKSIZE
1175
1176                 movzx ecx,word [pxe_udp_read_pkt.buffersize]
1177                 sub cx,2                ; CX <- bytes after opcode
1178                 jb .failure             ; Garbled reply
1179
1180                 mov si,packet_buf
1181                 lodsw
1182
1183                 cmp ax, TFTP_ERROR
1184                 je .bailnow             ; ERROR reply: don't try again
1185
1186                 ; If the server doesn't support any options, we'll get
1187                 ; a DATA reply instead of OACK.  Stash the data in
1188                 ; the file buffer and go with the default value for
1189                 ; all options...
1190                 cmp ax, TFTP_DATA
1191                 je .no_oack
1192
1193                 cmp ax, TFTP_OACK
1194                 jne .err_reply          ; Unknown packet type
1195
1196                 ; Now we need to parse the OACK packet to get the transfer
1197                 ; and packet sizes.
1198                 ;  SI -> first byte of options; [E]CX -> byte count
1199 .parse_oack:
1200                 jcxz .done_pkt                  ; No options acked
1201 .get_opt_name:
1202                 mov di,si
1203                 mov bx,si
1204 .opt_name_loop: lodsb
1205                 and al,al
1206                 jz .got_opt_name
1207                 or al,20h                       ; Convert to lowercase
1208                 stosb
1209                 loop .opt_name_loop
1210                 ; We ran out, and no final null
1211                 jmp .err_reply
1212 .got_opt_name:  ; si -> option value
1213                 dec cx                          ; bytes left in pkt
1214                 jz .err_reply                   ; Option w/o value
1215
1216                 ; Parse option pointed to by bx; guaranteed to be
1217                 ; null-terminated.
1218                 push cx
1219                 push si
1220                 mov si,bx                       ; -> option name
1221                 mov bx,tftp_opt_table
1222                 mov cx,tftp_opts
1223 .opt_loop:
1224                 push cx
1225                 push si
1226                 mov di,[bx]                     ; Option pointer
1227                 mov cx,[bx+2]                   ; Option len
1228                 repe cmpsb
1229                 pop si
1230                 pop cx
1231                 je .get_value                   ; OK, known option
1232                 add bx,6
1233                 loop .opt_loop
1234
1235                 pop si
1236                 pop cx
1237                 jmp .err_reply                  ; Non-negotiated option returned
1238
1239 .get_value:     pop si                          ; si -> option value
1240                 pop cx                          ; cx -> bytes left in pkt
1241                 mov bx,[bx+4]                   ; Pointer to data target
1242                 add bx,[bp-6]                   ; TFTP socket pointer
1243                 xor eax,eax
1244                 xor edx,edx
1245 .value_loop:    lodsb
1246                 and al,al
1247                 jz .got_value
1248                 sub al,'0'
1249                 cmp al, 9
1250                 ja .err_reply                   ; Not a decimal digit
1251                 imul edx,10
1252                 add edx,eax
1253                 mov [bx],edx
1254                 loop .value_loop
1255                 ; Ran out before final null, accept anyway
1256                 jmp short .done_pkt
1257
1258 .got_value:
1259                 dec cx
1260                 jnz .get_opt_name               ; Not end of packet
1261
1262                 ; ZF == 1
1263
1264                 ; Success, done!
1265 .done_pkt:
1266                 pop si                  ; Junk
1267                 pop si                  ; We want the packet ptr in SI
1268
1269                 mov eax,[si+tftp_filesize]
1270                 and eax,eax             ; Set ZF depending on file size
1271                 pop bp                  ; Junk
1272                 pop bp                  ; Junk (retry counter)
1273                 jz .error_si            ; ZF = 1 need to free the socket
1274 .ret:
1275                 pop bp
1276                 pop cx
1277                 pop bx
1278                 pop es
1279                 ret
1280
1281
1282 .no_oack:       ; We got a DATA packet, meaning no options are
1283                 ; suported.  Save the data away and consider the length
1284                 ; undefined, *unless* this is the only data packet...
1285                 mov bx,[bp-6]           ; File pointer
1286                 sub cx,2                ; Too short?
1287                 jb .failure
1288                 lodsw                   ; Block number
1289                 cmp ax,1
1290                 jne .failure
1291                 mov [bx+tftp_lastpkt],ax
1292                 cmp cx,TFTP_BLOCKSIZE
1293                 ja .err_reply           ; Corrupt...
1294                 je .unknown_size
1295                 mov [bx+tftp_filesize],ecx
1296 .unknown_size:  mov [bx+tftp_bytesleft],cx
1297                 mov ax,pktbuf_seg
1298                 push es
1299                 mov es,ax
1300                 mov di,tftp_pktbuf
1301                 mov [bx+tftp_dataptr],di
1302                 add cx,3
1303                 shr cx,2
1304                 rep movsd
1305                 pop es
1306                 jmp .done_pkt
1307
1308 .err_reply:     ; Option negotiation error.  Send ERROR reply.
1309                 ; ServerIP and gateway are already programmed in
1310                 mov si,[bp-6]
1311                 mov ax,[si+tftp_remoteport]
1312                 mov word [pxe_udp_write_pkt.rport],ax
1313                 mov word [pxe_udp_write_pkt.buffer],tftp_opt_err
1314                 mov word [pxe_udp_write_pkt.buffersize],tftp_opt_err_len
1315                 mov di,pxe_udp_write_pkt
1316                 mov bx,PXENV_UDP_WRITE
1317                 call pxenv
1318
1319                 ; Write an error message and explode
1320                 mov si,err_oldtftp
1321                 call writestr
1322                 jmp kaboom
1323
1324 .bailnow:       mov word [bp-2],1       ; Immediate error - no retry
1325
1326 .failure:       pop bx                  ; Junk
1327                 pop bx
1328                 pop si
1329                 pop ax
1330                 dec ax                  ; Retry counter
1331                 jnz .sendreq            ; Try again
1332
1333 .error:         mov si,bx               ; Socket pointer
1334 .error_si:                              ; Socket pointer already in SI
1335                 call free_socket        ; ZF <- 1, SI <- 0
1336                 jmp .ret
1337
1338 ;
1339 ; allocate_socket: Allocate a local UDP port structure
1340 ;
1341 ;               If successful:
1342 ;                 ZF set
1343 ;                 BX     = socket pointer
1344 ;               If unsuccessful:
1345 ;                 ZF clear
1346 ;
1347 allocate_socket:
1348                 push cx
1349                 mov bx,Files
1350                 mov cx,MAX_OPEN
1351 .check:         cmp word [bx], byte 0
1352                 je .found
1353                 add bx,open_file_t_size
1354                 loop .check
1355                 xor cx,cx                       ; ZF = 1
1356                 pop cx
1357                 ret
1358                 ; Allocate a socket number.  Socket numbers are made
1359                 ; guaranteed unique by including the socket slot number
1360                 ; (inverted, because we use the loop counter cx); add a
1361                 ; counter value to keep the numbers from being likely to
1362                 ; get immediately reused.
1363                 ;
1364                 ; The NextSocket variable also contains the top two bits
1365                 ; set.  This generates a value in the range 49152 to
1366                 ; 57343.
1367 .found:
1368                 dec cx
1369                 push ax
1370                 mov ax,[NextSocket]
1371                 inc ax
1372                 and ax,((1 << (13-MAX_OPEN_LG2))-1) | 0xC000
1373                 mov [NextSocket],ax
1374                 shl cx,13-MAX_OPEN_LG2
1375                 add cx,ax                       ; ZF = 0
1376                 xchg ch,cl                      ; Convert to network byte order
1377                 mov [bx],cx                     ; Socket in use
1378                 pop ax
1379                 pop cx
1380                 ret
1381
1382 ;
1383 ; Free socket: socket in SI; return SI = 0, ZF = 1 for convenience
1384 ;
1385 free_socket:
1386                 push es
1387                 pusha
1388                 xor ax,ax
1389                 mov es,ax
1390                 mov di,si
1391                 mov cx,tftp_pktbuf >> 1         ; tftp_pktbuf is not cleared
1392                 rep stosw
1393                 popa
1394                 pop es
1395                 xor si,si
1396                 ret
1397
1398 ;
1399 ; parse_dotquad:
1400 ;               Read a dot-quad pathname in DS:SI and output an IP
1401 ;               address in EAX, with SI pointing to the first
1402 ;               nonmatching character.
1403 ;
1404 ;               Return CF=1 on error.
1405 ;
1406 ;               No segment assumptions permitted.
1407 ;
1408 parse_dotquad:
1409                 push cx
1410                 mov cx,4
1411                 xor eax,eax
1412 .parseloop:
1413                 mov ch,ah
1414                 mov ah,al
1415                 lodsb
1416                 sub al,'0'
1417                 jb .notnumeric
1418                 cmp al,9
1419                 ja .notnumeric
1420                 aad                             ; AL += 10 * AH; AH = 0;
1421                 xchg ah,ch
1422                 jmp .parseloop
1423 .notnumeric:
1424                 cmp al,'.'-'0'
1425                 pushf
1426                 mov al,ah
1427                 mov ah,ch
1428                 xor ch,ch
1429                 ror eax,8
1430                 popf
1431                 jne .error
1432                 loop .parseloop
1433                 jmp .done
1434 .error:
1435                 loop .realerror                 ; If CX := 1 then we're done
1436                 clc
1437                 jmp .done
1438 .realerror:
1439                 stc
1440 .done:
1441                 dec si                          ; CF unchanged!
1442                 pop cx
1443                 ret
1444 ;
1445 ; mangle_name: Mangle a filename pointed to by DS:SI into a buffer pointed
1446 ;              to by ES:DI; ends on encountering any whitespace.
1447 ;              DI is preserved.
1448 ;
1449 ;              This verifies that a filename is < FILENAME_MAX characters
1450 ;              and doesn't contain whitespace, and zero-pads the output buffer,
1451 ;              so "repe cmpsb" can do a compare.
1452 ;
1453 ;              The first four bytes of the manged name is the IP address of
1454 ;              the download host.
1455 ;
1456 ;              No segment assumptions permitted.
1457 ;
1458 mangle_name:
1459                 push di
1460                 push si
1461                 mov eax,[cs:ServerIP]
1462                 cmp byte [si],0
1463                 je .noip                        ; Null filename?!?!
1464                 cmp word [si],'::'              ; Leading ::?
1465                 je .gotprefix
1466
1467 .more:
1468                 inc si
1469                 cmp byte [si],0
1470                 je .noip
1471                 cmp word [si],'::'
1472                 jne .more
1473
1474                 ; We have a :: prefix of some sort, it could be either
1475                 ; a DNS name or a dot-quad IP address.  Try the dot-quad
1476                 ; first...
1477 .here:
1478                 pop si
1479                 push si
1480                 call parse_dotquad
1481                 jc .notdq
1482                 cmp word [si],'::'
1483                 je .gotprefix
1484 .notdq:
1485                 pop si
1486                 push si
1487                 call dns_resolv
1488                 cmp word [si],'::'
1489                 jne .noip
1490                 and eax,eax
1491                 jnz .gotprefix
1492
1493 .noip:
1494                 pop si
1495                 xor eax,eax
1496                 jmp .prefix_done
1497
1498 .gotprefix:
1499                 pop cx                          ; Adjust stack
1500                 inc si                          ; Skip double colon
1501                 inc si
1502
1503 .prefix_done:
1504                 stosd                           ; Save IP address prefix
1505                 mov cx,FILENAME_MAX-5
1506
1507 .mn_loop:
1508                 lodsb
1509                 cmp al,' '                      ; If control or space, end
1510                 jna .mn_end
1511                 stosb
1512                 loop .mn_loop
1513 .mn_end:
1514                 inc cx                          ; At least one null byte
1515                 xor ax,ax                       ; Zero-fill name
1516                 rep stosb                       ; Doesn't do anything if CX=0
1517                 pop di
1518                 ret                             ; Done
1519
1520 ;
1521 ; unmangle_name: Does the opposite of mangle_name; converts a DOS-mangled
1522 ;                filename to the conventional representation.  This is needed
1523 ;                for the BOOT_IMAGE= parameter for the kernel.
1524 ;
1525 ;                NOTE: The output buffer needs to be able to hold an
1526 ;                expanded IP address.
1527 ;
1528 ;                DS:SI -> input mangled file name
1529 ;                ES:DI -> output buffer
1530 ;
1531 ;                On return, DI points to the first byte after the output name,
1532 ;                which is set to a null byte.
1533 ;
1534 unmangle_name:
1535                 push eax
1536                 lodsd
1537                 and eax,eax
1538                 jz .noip
1539                 call gendotquad
1540                 mov ax,'::'
1541                 stosw
1542 .noip:
1543                 call strcpy
1544                 dec di                          ; Point to final null byte
1545                 pop eax
1546                 ret
1547
1548 ;
1549 ; pxenv
1550 ;
1551 ; This is the main PXENV+/!PXE entry point, using the PXENV+
1552 ; calling convention.  This is a separate local routine so
1553 ; we can hook special things from it if necessary.  In particular,
1554 ; some PXE stacks seem to not like being invoked from anything but
1555 ; the initial stack, so humour it.
1556 ;
1557
1558 pxenv:
1559 %if USE_PXE_PROVIDED_STACK == 0
1560                 mov [cs:PXEStack],sp
1561                 mov [cs:PXEStack+2],ss
1562                 lss sp,[cs:InitStack]
1563 %endif
1564 .jump:          call 0:pxe_thunk                ; Default to calling the thunk
1565 %if USE_PXE_PROVIDED_STACK == 0
1566                 lss sp,[cs:PXEStack]
1567 %endif
1568                 cld                             ; Make sure DF <- 0
1569                 ret
1570
1571 ; Must be after function def due to NASM bug
1572 PXENVEntry      equ pxenv.jump+1
1573
1574 ;
1575 ; pxe_thunk
1576 ;
1577 ; Convert from the PXENV+ calling convention (BX, ES, DI) to the !PXE
1578 ; calling convention (using the stack.)
1579 ;
1580 ; This is called as a far routine so that we can just stick it into
1581 ; the PXENVEntry variable.
1582 ;
1583 pxe_thunk:      push es
1584                 push di
1585                 push bx
1586 .jump:          call 0:0
1587                 add sp,byte 6
1588                 cmp ax,byte 1
1589                 cmc                             ; Set CF unless ax == 0
1590                 retf
1591
1592 ; Must be after function def due to NASM bug
1593 PXEEntry        equ pxe_thunk.jump+1
1594
1595 ;
1596 ; getfssec: Get multiple clusters from a file, given the starting cluster.
1597 ;
1598 ;       In this case, get multiple blocks from a specific TCP connection.
1599 ;
1600 ;  On entry:
1601 ;       ES:BX   -> Buffer
1602 ;       SI      -> TFTP socket pointer
1603 ;       CX      -> 512-byte block count; 0FFFFh = until end of file
1604 ;  On exit:
1605 ;       SI      -> TFTP socket pointer (or 0 on EOF)
1606 ;       CF = 1  -> Hit EOF
1607 ;       ECX     -> number of bytes actually read
1608 ;
1609 getfssec:       push eax
1610                 push edi
1611                 push bx
1612                 push si
1613                 push fs
1614                 mov di,bx
1615                 mov ax,pktbuf_seg
1616                 mov fs,ax
1617
1618                 xor eax,eax
1619                 movzx ecx,cx
1620                 shl ecx,TFTP_BLOCKSIZE_LG2      ; Convert to bytes
1621                 push ecx                        ; Initial request size
1622                 jz .hit_eof                     ; Nothing to do?
1623
1624 .need_more:
1625                 call fill_buffer
1626                 movzx eax,word [si+tftp_bytesleft]
1627                 and ax,ax
1628                 jz .hit_eof
1629
1630                 push ecx
1631                 cmp ecx,eax
1632                 jna .ok_size
1633                 mov ecx,eax
1634 .ok_size:
1635                 mov ax,cx                       ; EAX<31:16> == ECX<31:16> == 0
1636                 mov bx,[si+tftp_dataptr]
1637                 sub [si+tftp_bytesleft],cx
1638                 xchg si,bx
1639                 fs rep movsb                    ; Copy from packet buffer
1640                 xchg si,bx
1641                 mov [si+tftp_dataptr],bx
1642
1643                 pop ecx
1644                 sub ecx,eax
1645                 jnz .need_more
1646
1647 .hit_eof:
1648                 call fill_buffer
1649
1650                 pop eax                         ; Initial request amount
1651                 xchg eax,ecx
1652                 sub ecx,eax                     ; ... minus anything not gotten
1653
1654                 pop fs
1655                 pop si
1656
1657                 ; Is there anything left of this?
1658                 mov eax,[si+tftp_filesize]
1659                 sub eax,[si+tftp_filepos]
1660                 jnz .bytes_left
1661
1662                 cmp [si+tftp_bytesleft],ax      ; AX == 0
1663                 jne .bytes_left
1664
1665                 cmp byte [si+tftp_goteof],0
1666                 je .done
1667                 ; I'm 99% sure this can't happen, but...
1668                 call fill_buffer                ; Receive/ACK the EOF packet
1669 .done:
1670                 ; The socket is closed and the buffer drained
1671                 ; Close socket structure and re-init for next user
1672                 call free_socket
1673                 stc
1674                 jmp .ret
1675 .bytes_left:
1676                 clc
1677 .ret:
1678                 pop bx
1679                 pop edi
1680                 pop eax
1681                 ret
1682
1683 ;
1684 ; Get a fresh packet if the buffer is drained, and we haven't hit
1685 ; EOF yet.  The buffer should be filled immediately after draining!
1686 ;
1687 ; expects fs -> pktbuf_seg and ds:si -> socket structure
1688 ;
1689 fill_buffer:
1690                 cmp word [si+tftp_bytesleft],0
1691                 je .empty
1692                 ret                             ; Otherwise, nothing to do
1693
1694 .empty:
1695                 push es
1696                 pushad
1697                 mov ax,ds
1698                 mov es,ax
1699
1700                 ; Note: getting the EOF packet is not the same thing
1701                 ; as tftp_filepos == tftp_filesize; if the EOF packet
1702                 ; is empty the latter condition can be true without
1703                 ; having gotten the official EOF.
1704                 cmp byte [si+tftp_goteof],0
1705                 jne .ret                        ; Alread EOF
1706
1707 .packet_loop:
1708                 ; Start by ACKing the previous packet; this should cause the
1709                 ; next packet to be sent.
1710                 mov cx,PKT_RETRY
1711                 mov word [PktTimeout],PKT_TIMEOUT
1712
1713 .send_ack:      push cx                         ; <D> Retry count
1714
1715                 mov ax,[si+tftp_lastpkt]
1716                 call ack_packet                 ; Send ACK
1717
1718                 ; We used to test the error code here, but sometimes
1719                 ; PXE would return negative status even though we really
1720                 ; did send the ACK.  Now, just treat a failed send as
1721                 ; a normally lost packet, and let it time out in due
1722                 ; course of events.
1723
1724 .send_ok:       ; Now wait for packet.
1725                 mov dx,[BIOS_timer]             ; Get current time
1726
1727                 mov cx,[PktTimeout]
1728 .wait_data:     push cx                         ; <E> Timeout
1729                 push dx                         ; <F> Old time
1730
1731                 mov bx,[si+tftp_pktbuf]
1732                 mov [pxe_udp_read_pkt.buffer],bx
1733                 mov [pxe_udp_read_pkt.buffer+2],fs
1734                 mov [pxe_udp_read_pkt.buffersize],word PKTBUF_SIZE
1735                 mov eax,[si+tftp_remoteip]
1736                 mov [pxe_udp_read_pkt.sip],eax
1737                 mov eax,[MyIP]
1738                 mov [pxe_udp_read_pkt.dip],eax
1739                 mov ax,[si+tftp_remoteport]
1740                 mov [pxe_udp_read_pkt.rport],ax
1741                 mov ax,[si+tftp_localport]
1742                 mov [pxe_udp_read_pkt.lport],ax
1743                 mov di,pxe_udp_read_pkt
1744                 mov bx,PXENV_UDP_READ
1745                 push si                         ; <G>
1746                 call pxenv
1747                 pop si                          ; <G>
1748                 and ax,ax
1749                 jz .recv_ok
1750
1751                 ; No packet, or receive failure
1752                 mov dx,[BIOS_timer]
1753                 pop ax                          ; <F> Old time
1754                 pop cx                          ; <E> Timeout
1755                 cmp ax,dx                       ; Same time -> don't advance timeout
1756                 je .wait_data                   ; Same clock tick
1757                 loop .wait_data                 ; Decrease timeout
1758
1759                 pop cx                          ; <D> Didn't get any, send another ACK
1760                 shl word [PktTimeout],1         ; Exponential backoff
1761                 loop .send_ack
1762                 jmp kaboom                      ; Forget it...
1763
1764 .recv_ok:       pop dx                          ; <F>
1765                 pop cx                          ; <E>
1766
1767                 cmp word [pxe_udp_read_pkt.buffersize],byte 4
1768                 jb .wait_data                   ; Bad size for a DATA packet
1769
1770                 mov bx,[si+tftp_pktbuf]
1771                 cmp word [fs:bx],TFTP_DATA      ; Not a data packet?
1772                 jne .wait_data                  ; Then wait for something else
1773
1774                 mov ax,[si+tftp_lastpkt]
1775                 xchg ah,al                      ; Host byte order
1776                 inc ax                          ; Which packet are we waiting for?
1777                 xchg ah,al                      ; Network byte order
1778                 cmp [fs:bx+2],ax
1779                 je .right_packet
1780
1781                 ; Wrong packet, ACK the packet and then try again
1782                 ; This is presumably because the ACK got lost,
1783                 ; so the server just resent the previous packet
1784                 mov ax,[fs:bx+2]
1785                 call ack_packet
1786                 jmp .send_ok                    ; Reset timeout
1787
1788 .right_packet:  ; It's the packet we want.  We're also EOF if the
1789                 ; size < blocksize
1790
1791                 pop cx                          ; <D> Don't need the retry count anymore
1792
1793                 mov [si+tftp_lastpkt],ax        ; Update last packet number
1794
1795                 movzx ecx,word [pxe_udp_read_pkt.buffersize]
1796                 sub cx,byte 4                   ; Skip TFTP header
1797
1798                 ; Set pointer to data block
1799                 lea ax,[bx+4]                   ; Data past TFTP header
1800                 mov [si+tftp_dataptr],ax
1801
1802                 add [si+tftp_filepos],ecx
1803                 mov [si+tftp_bytesleft],cx
1804
1805                 cmp cx,[si+tftp_blksize]        ; Is it a full block?
1806                 jb .last_block                  ; If not, it's EOF
1807
1808 .ret:
1809                 popad
1810                 pop es
1811                 ret
1812
1813
1814 .last_block:    ; Last block - ACK packet immediately
1815                 TRACER 'L'
1816                 mov ax,[fs:bx+2]
1817                 call ack_packet
1818
1819                 ; Make sure we know we are at end of file
1820                 mov eax,[si+tftp_filepos]
1821                 mov [si+tftp_filesize],eax
1822                 mov byte [si+tftp_goteof],1
1823
1824                 jmp .ret
1825
1826 ;
1827 ; ack_packet:
1828 ;
1829 ; Send ACK packet.  This is a common operation and so is worth canning.
1830 ;
1831 ; Entry:
1832 ;       SI      = TFTP block
1833 ;       AX      = Packet # to ack (network byte order)
1834 ; Exit:
1835 ;       ZF = 0 -> Error
1836 ;       All registers preserved
1837 ;
1838 ; This function uses the pxe_udp_write_pkt but not the packet_buf.
1839 ;
1840 ack_packet:
1841                 pushad
1842                 mov [ack_packet_buf+2],ax       ; Packet number to ack
1843                 mov ax,[si]
1844                 mov [pxe_udp_write_pkt.lport],ax
1845                 mov ax,[si+tftp_remoteport]
1846                 mov [pxe_udp_write_pkt.rport],ax
1847                 mov eax,[si+tftp_remoteip]
1848                 mov [pxe_udp_write_pkt.sip],eax
1849                 xor eax,[MyIP]
1850                 and eax,[Netmask]
1851                 jz .nogw
1852                 mov eax,[Gateway]
1853 .nogw:
1854                 mov [pxe_udp_write_pkt.gip],eax
1855                 mov [pxe_udp_write_pkt.buffer],word ack_packet_buf
1856                 mov [pxe_udp_write_pkt.buffersize], word 4
1857                 mov di,pxe_udp_write_pkt
1858                 mov bx,PXENV_UDP_WRITE
1859                 call pxenv
1860                 cmp ax,byte 0                   ; ZF = 1 if write OK
1861                 popad
1862                 ret
1863
1864 ;
1865 ; unload_pxe:
1866 ;
1867 ; This function unloads the PXE and UNDI stacks and unclaims
1868 ; the memory.
1869 ;
1870 unload_pxe:
1871                 test byte [KeepPXE],01h         ; Should we keep PXE around?
1872                 jnz reset_pxe
1873
1874                 push ds
1875                 push es
1876
1877                 mov ax,cs
1878                 mov ds,ax
1879                 mov es,ax
1880
1881                 mov si,new_api_unload
1882                 cmp byte [APIVer+1],2           ; Major API version >= 2?
1883                 jae .new_api
1884                 mov si,old_api_unload
1885 .new_api:
1886
1887 .call_loop:     xor ax,ax
1888                 lodsb
1889                 and ax,ax
1890                 jz .call_done
1891                 xchg bx,ax
1892                 mov di,pxe_unload_stack_pkt
1893                 push di
1894                 xor ax,ax
1895                 mov cx,pxe_unload_stack_pkt_len >> 1
1896                 rep stosw
1897                 pop di
1898                 call pxenv
1899                 jc .cant_free
1900                 mov ax,word [pxe_unload_stack_pkt.status]
1901                 cmp ax,PXENV_STATUS_SUCCESS
1902                 jne .cant_free
1903                 jmp .call_loop
1904
1905 .call_done:
1906                 mov bx,0FF00h
1907
1908                 mov dx,[RealBaseMem]
1909                 cmp dx,[BIOS_fbm]               ; Sanity check
1910                 jna .cant_free
1911                 inc bx
1912
1913                 ; Check that PXE actually unhooked the INT 1Ah chain
1914                 movzx eax,word [4*0x1a]
1915                 movzx ecx,word [4*0x1a+2]
1916                 shl ecx,4
1917                 add eax,ecx
1918                 shr eax,10
1919                 cmp ax,dx                       ; Not in range
1920                 jae .ok
1921                 cmp ax,[BIOS_fbm]
1922                 jae .cant_free
1923                 ; inc bx
1924
1925 .ok:
1926                 mov [BIOS_fbm],dx
1927 .pop_ret:
1928                 pop es
1929                 pop ds
1930                 ret
1931
1932 .cant_free:
1933                 mov si,cant_free_msg
1934                 call writestr
1935                 push ax
1936                 xchg bx,ax
1937                 call writehex4
1938                 mov al,'-'
1939                 call writechr
1940                 pop ax
1941                 call writehex4
1942                 mov al,'-'
1943                 call writechr
1944                 mov eax,[4*0x1a]
1945                 call writehex8
1946                 call crlf
1947                 jmp .pop_ret
1948
1949                 ; We want to keep PXE around, but still we should reset
1950                 ; it to the standard bootup configuration
1951 reset_pxe:
1952                 push es
1953                 push cs
1954                 pop es
1955                 mov bx,PXENV_UDP_CLOSE
1956                 mov di,pxe_udp_close_pkt
1957                 call pxenv
1958                 pop es
1959                 ret
1960
1961 ;
1962 ; gendotquad
1963 ;
1964 ; Take an IP address (in network byte order) in EAX and
1965 ; output a dotted quad string to ES:DI.
1966 ; DI points to terminal null at end of string on exit.
1967 ;
1968 gendotquad:
1969                 push eax
1970                 push cx
1971                 mov cx,4
1972 .genchar:
1973                 push eax
1974                 cmp al,10               ; < 10?
1975                 jb .lt10                ; If so, skip first 2 digits
1976
1977                 cmp al,100              ; < 100
1978                 jb .lt100               ; If so, skip first digit
1979
1980                 aam 100
1981                 ; Now AH = 100-digit; AL = remainder
1982                 add ah,'0'
1983                 mov [es:di],ah
1984                 inc di
1985
1986 .lt100:
1987                 aam 10
1988                 ; Now AH = 10-digit; AL = remainder
1989                 add ah,'0'
1990                 mov [es:di],ah
1991                 inc di
1992
1993 .lt10:
1994                 add al,'0'
1995                 stosb
1996                 mov al,'.'
1997                 stosb
1998                 pop eax
1999                 ror eax,8       ; Move next char into LSB
2000                 loop .genchar
2001                 dec di
2002                 mov [es:di], byte 0
2003                 pop cx
2004                 pop eax
2005                 ret
2006 ;
2007 ; uchexbytes/lchexbytes
2008 ;
2009 ; Take a number of bytes in memory and convert to upper/lower-case
2010 ; hexadecimal
2011 ;
2012 ; Input:
2013 ;       DS:SI   = input bytes
2014 ;       ES:DI   = output buffer
2015 ;       CX      = number of bytes
2016 ; Output:
2017 ;       DS:SI   = first byte after
2018 ;       ES:DI   = first byte after
2019 ;       CX = 0
2020 ;
2021 ; Trashes AX, DX
2022 ;
2023
2024 lchexbytes:
2025         mov dl,'a'-'9'-1
2026         jmp xchexbytes
2027 uchexbytes:
2028         mov dl,'A'-'9'-1
2029 xchexbytes:
2030 .loop:
2031         lodsb
2032         mov ah,al
2033         shr al,4
2034         call .outchar
2035         mov al,ah
2036         call .outchar
2037         loop .loop
2038         ret
2039 .outchar:
2040         and al,0Fh
2041         add al,'0'
2042         cmp al,'9'
2043         jna .done
2044         add al,dl
2045 .done:
2046         stosb
2047         ret
2048
2049 ;
2050 ; pxe_get_cached_info
2051 ;
2052 ; Get a DHCP packet from the PXE stack into the trackbuf.
2053 ;
2054 ; Input:
2055 ;       DL = packet type
2056 ; Output:
2057 ;       CX = buffer size
2058 ;
2059 ; Assumes CS == DS == ES.
2060 ;
2061 pxe_get_cached_info:
2062                 pushad
2063                 mov di,pxe_bootp_query_pkt
2064                 push di
2065                 xor ax,ax
2066                 stosw           ; Status
2067                 movzx ax,dl
2068                 stosw           ; Packet type
2069                 mov ax,trackbufsize
2070                 stosw           ; Buffer size
2071                 mov ax,trackbuf
2072                 stosw           ; Buffer offset
2073                 xor ax,ax
2074                 stosw           ; Buffer segment
2075
2076                 pop di          ; DI -> parameter set
2077                 mov bx,PXENV_GET_CACHED_INFO
2078                 call pxenv
2079                 jc .err
2080                 and ax,ax
2081                 jnz .err
2082
2083                 popad
2084                 mov cx,[pxe_bootp_query_pkt.buffersize]
2085                 ret
2086
2087 .err:
2088                 mov si,err_pxefailed
2089                 jmp kaboom
2090
2091 ;
2092 ; parse_dhcp
2093 ;
2094 ; Parse a DHCP packet.  This includes dealing with "overloaded"
2095 ; option fields (see RFC 2132, section 9.3)
2096 ;
2097 ; This should fill in the following global variables, if the
2098 ; information is present:
2099 ;
2100 ; MyIP          - client IP address
2101 ; ServerIP      - boot server IP address
2102 ; Netmask       - network mask
2103 ; Gateway       - default gateway router IP
2104 ; BootFile      - boot file name
2105 ; DNSServers    - DNS server IPs
2106 ; LocalDomain   - Local domain name
2107 ; MACLen, MAC   - Client identifier, if MACLen == 0
2108 ;
2109 ; This assumes the DHCP packet is in "trackbuf" and the length
2110 ; of the packet in in CX on entry.
2111 ;
2112
2113 parse_dhcp:
2114                 mov byte [OverLoad],0           ; Assume no overload
2115                 mov eax, [trackbuf+bootp.yip]
2116                 and eax, eax
2117                 jz .noyip
2118                 cmp al,224                      ; Class D or higher -> bad
2119                 jae .noyip
2120                 mov [MyIP], eax
2121 .noyip:
2122                 mov eax, [trackbuf+bootp.sip]
2123                 and eax, eax
2124                 jz .nosip
2125                 cmp al,224                      ; Class D or higher -> bad
2126                 jae .nosip
2127                 mov [ServerIP], eax
2128 .nosip:
2129                 sub cx, bootp.options
2130                 jbe .nooptions
2131                 mov si, trackbuf+bootp.option_magic
2132                 lodsd
2133                 cmp eax, BOOTP_OPTION_MAGIC
2134                 jne .nooptions
2135                 call parse_dhcp_options
2136 .nooptions:
2137                 mov si, trackbuf+bootp.bootfile
2138                 test byte [OverLoad],1
2139                 jz .nofileoverload
2140                 mov cx,128
2141                 call parse_dhcp_options
2142                 jmp short .parsed_file
2143 .nofileoverload:
2144                 cmp byte [si], 0
2145                 jz .parsed_file                 ; No bootfile name
2146                 mov di,BootFile
2147                 mov cx,32
2148                 rep movsd
2149                 xor al,al
2150                 stosb                           ; Null-terminate
2151 .parsed_file:
2152                 mov si, trackbuf+bootp.sname
2153                 test byte [OverLoad],2
2154                 jz .nosnameoverload
2155                 mov cx,64
2156                 call parse_dhcp_options
2157 .nosnameoverload:
2158                 ret
2159
2160 ;
2161 ; Parse a sequence of DHCP options, pointed to by DS:SI; the field
2162 ; size is CX -- some DHCP servers leave option fields unterminated
2163 ; in violation of the spec.
2164 ;
2165 ; For parse_some_dhcp_options, DH contains the minimum value for
2166 ; the option to recognize -- this is used to restrict parsing to
2167 ; PXELINUX-specific options only.
2168 ;
2169 parse_dhcp_options:
2170                 xor dx,dx
2171
2172 parse_some_dhcp_options:
2173 .loop:
2174                 and cx,cx
2175                 jz .done
2176
2177                 lodsb
2178                 dec cx
2179                 jz .done        ; Last byte; must be PAD, END or malformed
2180                 cmp al, 0       ; PAD option
2181                 je .loop
2182                 cmp al,255      ; END option
2183                 je .done
2184
2185                 ; Anything else will have a length field
2186                 mov dl,al       ; DL <- option number
2187                 xor ax,ax
2188                 lodsb           ; AX <- option length
2189                 dec cx
2190                 sub cx,ax       ; Decrement bytes left counter
2191                 jb .done        ; Malformed option: length > field size
2192
2193                 cmp dl,dh       ; Is the option value valid?
2194                 jb .opt_done
2195
2196                 mov bx,dhcp_option_list
2197 .find_option:
2198                 cmp bx,dhcp_option_list_end
2199                 jae .opt_done
2200                 cmp dl,[bx]
2201                 je .found_option
2202                 add bx,3
2203                 jmp .find_option
2204 .found_option:
2205                 pushad
2206                 call [bx+1]
2207                 popad
2208
2209 ; Fall through
2210                 ; Unknown option.  Skip to the next one.
2211 .opt_done:
2212                 add si,ax
2213                 jmp .loop
2214 .done:
2215                 ret
2216
2217                 section .data
2218 dhcp_option_list:
2219                 section .text
2220
2221 %macro dopt 2
2222                 section .data
2223                 db %1
2224                 dw dopt_%2
2225                 section .text
2226 dopt_%2:
2227 %endmacro
2228
2229 ;
2230 ; Parse individual DHCP options.  SI points to the option data and
2231 ; AX to the option length.  DL contains the option number.
2232 ; All registers are saved around the routine.
2233 ;
2234         dopt 1, subnet_mask
2235                 mov ebx,[si]
2236                 mov [Netmask],ebx
2237                 ret
2238
2239         dopt 3, router
2240                 mov ebx,[si]
2241                 mov [Gateway],ebx
2242                 ret
2243
2244         dopt 6, dns_servers
2245                 mov cx,ax
2246                 shr cx,2
2247                 cmp cl,DNS_MAX_SERVERS
2248                 jna .oklen
2249                 mov cl,DNS_MAX_SERVERS
2250 .oklen:
2251                 mov di,DNSServers
2252                 rep movsd
2253                 mov [LastDNSServer],di
2254                 ret
2255
2256         dopt 16, local_domain
2257                 mov bx,si
2258                 add bx,ax
2259                 xor ax,ax
2260                 xchg [bx],al    ; Zero-terminate option
2261                 mov di,LocalDomain
2262                 call dns_mangle ; Convert to DNS label set
2263                 mov [bx],al     ; Restore ending byte
2264                 ret
2265
2266         dopt 43, vendor_encaps
2267                 mov dh,208      ; Only recognize PXELINUX options
2268                 mov cx,ax       ; Length of option = max bytes to parse
2269                 call parse_some_dhcp_options    ; Parse recursive structure
2270                 ret
2271
2272         dopt 52, option_overload
2273                 mov bl,[si]
2274                 mov [OverLoad],bl
2275                 ret
2276
2277         dopt 54, server
2278                 mov eax,[si]
2279                 cmp dword [ServerIP],0
2280                 jne .skip               ; Already have a next server IP
2281                 cmp al,224              ; Class D or higher
2282                 jae .skip
2283                 mov [ServerIP],eax
2284 .skip:          ret
2285
2286         dopt 61, client_identifier
2287                 cmp ax,MAC_MAX          ; Too long?
2288                 ja .skip
2289                 cmp ax,2                ; Too short?
2290                 jb .skip
2291                 cmp [MACLen],ah         ; Only do this if MACLen == 0
2292                 jne .skip
2293                 push ax
2294                 lodsb                   ; Client identifier type
2295                 cmp al,[MACType]
2296                 pop ax
2297                 jne .skip               ; Client identifier is not a MAC
2298                 dec ax
2299                 mov [MACLen],al
2300                 mov di,MAC
2301                 jmp dhcp_copyoption
2302 .skip:          ret
2303
2304         dopt 67, bootfile_name
2305                 mov di,BootFile
2306                 jmp dhcp_copyoption
2307
2308         dopt 97, uuid_client_identifier
2309                 cmp ax,17               ; type byte + 16 bytes UUID
2310                 jne .skip
2311                 mov dl,[si]             ; Must have type 0 == UUID
2312                 or dl,[HaveUUID]        ; Capture only the first instance
2313                 jnz .skip
2314                 mov byte [HaveUUID],1   ; Got UUID
2315                 mov di,UUIDType
2316                 jmp dhcp_copyoption
2317 .skip:          ret
2318
2319         dopt 209, pxelinux_configfile
2320                 mov di,ConfigName
2321                 or byte [DHCPMagic],2   ; Got config file
2322                 jmp dhcp_copyoption
2323
2324         dopt 210, pxelinux_pathprefix
2325                 mov di,PathPrefix
2326                 or byte [DHCPMagic],4   ; Got path prefix
2327                 jmp dhcp_copyoption
2328
2329         dopt 211, pxelinux_reboottime
2330                 cmp al,4
2331                 jne .done
2332                 mov ebx,[si]
2333                 xchg bl,bh              ; Convert to host byte order
2334                 rol ebx,16
2335                 xchg bl,bh
2336                 mov [RebootTime],ebx
2337                 or byte [DHCPMagic],8   ; Got RebootTime
2338 .done:          ret
2339
2340                 ; Common code for copying an option verbatim
2341                 ; Copies the option into ES:DI and null-terminates it.
2342                 ; Returns with AX=0 and SI past the option.
2343 dhcp_copyoption:
2344                 xchg cx,ax      ; CX <- option length
2345                 rep movsb
2346                 xchg cx,ax      ; AX <- 0
2347                 stosb           ; Null-terminate
2348                 ret
2349
2350                 section .data
2351 dhcp_option_list_end:
2352                 section .text
2353
2354                 section .data
2355 HaveUUID        db 0
2356 uuid_dashes     db 4,2,2,2,6,0  ; Bytes per UUID dashed section
2357                 section .text
2358
2359 ;
2360 ; genipopt
2361 ;
2362 ; Generate an ip=<client-ip>:<boot-server-ip>:<gw-ip>:<netmask>
2363 ; option into IPOption based on a DHCP packet in trackbuf.
2364 ; Assumes CS == DS == ES.
2365 ;
2366 genipopt:
2367                 pushad
2368                 mov di,IPOption
2369                 mov eax,'ip='
2370                 stosd
2371                 dec di
2372                 mov eax,[MyIP]
2373                 call gendotquad
2374                 mov al,':'
2375                 stosb
2376                 mov eax,[ServerIP]
2377                 call gendotquad
2378                 mov al,':'
2379                 stosb
2380                 mov eax,[Gateway]
2381                 call gendotquad
2382                 mov al,':'
2383                 stosb
2384                 mov eax,[Netmask]
2385                 call gendotquad ; Zero-terminates its output
2386                 sub di,IPOption
2387                 mov [IPOptionLen],di
2388                 popad
2389                 ret
2390
2391 ;
2392 ; Call the receive loop while idle.  This is done mostly so we can respond to
2393 ; ARP messages, but perhaps in the future this can be used to do network
2394 ; console.
2395 ;
2396 ; hpa sez: people using automatic control on the serial port get very
2397 ; unhappy if we poll for ARP too often (the PXE stack is pretty slow,
2398 ; typically.)  Therefore, only poll if at least 4 BIOS timer ticks have
2399 ; passed since the last poll, and reset this when a character is
2400 ; received (RESET_IDLE).
2401 ;
2402 %if HAVE_IDLE
2403
2404 reset_idle:
2405                 push ax
2406                 mov ax,[cs:BIOS_timer]
2407                 mov [cs:IdleTimer],ax
2408                 pop ax
2409                 ret
2410
2411 check_for_arp:
2412                 push ax
2413                 mov ax,[cs:BIOS_timer]
2414                 sub ax,[cs:IdleTimer]
2415                 cmp ax,4
2416                 pop ax
2417                 jae .need_poll
2418                 ret
2419 .need_poll:     pushad
2420                 push ds
2421                 push es
2422                 mov ax,cs
2423                 mov ds,ax
2424                 mov es,ax
2425                 mov di,packet_buf
2426                 mov [pxe_udp_read_pkt.status],al        ; 0
2427                 mov [pxe_udp_read_pkt.buffer],di
2428                 mov [pxe_udp_read_pkt.buffer+2],ds
2429                 mov word [pxe_udp_read_pkt.buffersize],packet_buf_size
2430                 mov eax,[MyIP]
2431                 mov [pxe_udp_read_pkt.dip],eax
2432                 mov word [pxe_udp_read_pkt.lport],htons(9)      ; discard port
2433                 mov di,pxe_udp_read_pkt
2434                 mov bx,PXENV_UDP_READ
2435                 call pxenv
2436                 ; Ignore result...
2437                 pop es
2438                 pop ds
2439                 popad
2440                 RESET_IDLE
2441                 ret
2442
2443 %endif ; HAVE_IDLE
2444
2445 ; -----------------------------------------------------------------------------
2446 ;  Common modules
2447 ; -----------------------------------------------------------------------------
2448
2449 %include "getc.inc"             ; getc et al
2450 %include "conio.inc"            ; Console I/O
2451 %include "writestr.inc"         ; String output
2452 writestr        equ cwritestr
2453 %include "writehex.inc"         ; Hexadecimal output
2454 %include "configinit.inc"       ; Initialize configuration
2455 %include "parseconfig.inc"      ; High-level config file handling
2456 %include "parsecmd.inc"         ; Low-level config file handling
2457 %include "bcopy32.inc"          ; 32-bit bcopy
2458 %include "loadhigh.inc"         ; Load a file into high memory
2459 %include "font.inc"             ; VGA font stuff
2460 %include "graphics.inc"         ; VGA graphics
2461 %include "highmem.inc"          ; High memory sizing
2462 %include "strcpy.inc"           ; strcpy()
2463 %include "rawcon.inc"           ; Console I/O w/o using the console functions
2464 %include "dnsresolv.inc"        ; DNS resolver
2465 %include "adv.inc"              ; Auxillary Data Vector
2466
2467 ; -----------------------------------------------------------------------------
2468 ;  Begin data section
2469 ; -----------------------------------------------------------------------------
2470
2471                 section .data
2472
2473 copyright_str   db ' Copyright (C) 1994-', year, ' H. Peter Anvin'
2474                 db CR, LF, 0
2475 err_bootfailed  db CR, LF, 'Boot failed: press a key to retry, or wait for reset...', CR, LF, 0
2476 bailmsg         equ err_bootfailed
2477 err_nopxe       db "No !PXE or PXENV+ API found; we're dead...", CR, LF, 0
2478 err_pxefailed   db 'PXE API call failed, error ', 0
2479 err_udpinit     db 'Failed to initialize UDP stack', CR, LF, 0
2480 err_noconfig    db 'Unable to locate configuration file', CR, LF, 0
2481 err_oldtftp     db 'TFTP server does not support the tsize option', CR, LF, 0
2482 found_pxenv     db 'Found PXENV+ structure', CR, LF, 0
2483 using_pxenv_msg db 'Old PXE API detected, using PXENV+ structure', CR, LF, 0
2484 apiver_str      db 'PXE API version is ',0
2485 pxeentry_msg    db 'PXE entry point found (we hope) at ', 0
2486 pxenventry_msg  db 'PXENV entry point found (we hope) at ', 0
2487 trymempxe_msg   db 'Scanning memory for !PXE structure... ', 0
2488 trymempxenv_msg db 'Scanning memory for PXENV+ structure... ', 0
2489 undi_data_msg     db 'UNDI data segment at:   ',0
2490 undi_data_len_msg db 'UNDI data segment size: ',0
2491 undi_code_msg     db 'UNDI code segment at:   ',0
2492 undi_code_len_msg db 'UNDI code segment size: ',0
2493 cant_free_msg   db 'Failed to free base memory, error ', 0
2494 notfound_msg    db 'not found', CR, LF, 0
2495 myipaddr_msg    db 'My IP address seems to be ',0
2496 tftpprefix_msg  db 'TFTP prefix: ', 0
2497 localboot_msg   db 'Booting from local disk...', CR, LF, 0
2498 trying_msg      db 'Trying to load: ', 0
2499 fourbs_msg      db BS, BS, BS, BS, 0
2500 default_str     db 'default', 0
2501 syslinux_banner db CR, LF, 'PXELINUX ', version_str, ' ', date, ' ', 0
2502 cfgprefix       db 'pxelinux.cfg/'              ; No final null!
2503 cfgprefix_len   equ ($-cfgprefix)
2504
2505 ;
2506 ; Command line options we'd like to take a look at
2507 ;
2508 ; mem= and vga= are handled as normal 32-bit integer values
2509 initrd_cmd      db 'initrd='
2510 initrd_cmd_len  equ $-initrd_cmd
2511
2512 ; This one we make ourselves
2513 bootif_str      db 'BOOTIF='
2514 bootif_str_len  equ $-bootif_str
2515 ;
2516 ; Config file keyword table
2517 ;
2518 %include "keywords.inc"
2519
2520 ;
2521 ; Extensions to search for (in *forward* order).
2522 ; (.bs and .bss are disabled for PXELINUX, since they are not supported)
2523 ;
2524                 align 4, db 0
2525 exten_table:    db '.cbt'               ; COMBOOT (specific)
2526                 db '.0', 0, 0           ; PXE bootstrap program
2527                 db '.com'               ; COMBOOT (same as DOS)
2528                 db '.c32'               ; COM32
2529 exten_table_end:
2530                 dd 0, 0                 ; Need 8 null bytes here
2531
2532 ;
2533 ; PXE unload sequences
2534 ;
2535 new_api_unload:
2536                 db PXENV_UDP_CLOSE
2537                 db PXENV_UNDI_SHUTDOWN
2538                 db PXENV_UNLOAD_STACK
2539                 db PXENV_STOP_UNDI
2540                 db 0
2541 old_api_unload:
2542                 db PXENV_UDP_CLOSE
2543                 db PXENV_UNDI_SHUTDOWN
2544                 db PXENV_UNLOAD_STACK
2545                 db PXENV_UNDI_CLEANUP
2546                 db 0
2547
2548 ;
2549 ; PXE query packets partially filled in
2550 ;
2551                 section .bss
2552 pxe_bootp_query_pkt:
2553 .status:        resw 1                  ; Status
2554 .packettype:    resw 1                  ; Boot server packet type
2555 .buffersize:    resw 1                  ; Packet size
2556 .buffer:        resw 2                  ; seg:off of buffer
2557 .bufferlimit:   resw 1                  ; Unused
2558
2559                 section .data
2560 pxe_udp_open_pkt:
2561 .status:        dw 0                    ; Status
2562 .sip:           dd 0                    ; Source (our) IP
2563
2564 pxe_udp_close_pkt:
2565 .status:        dw 0                    ; Status
2566
2567 pxe_udp_write_pkt:
2568 .status:        dw 0                    ; Status
2569 .sip:           dd 0                    ; Server IP
2570 .gip:           dd 0                    ; Gateway IP
2571 .lport:         dw 0                    ; Local port
2572 .rport:         dw 0                    ; Remote port
2573 .buffersize:    dw 0                    ; Size of packet
2574 .buffer:        dw 0, 0                 ; seg:off of buffer
2575
2576 pxe_udp_read_pkt:
2577 .status:        dw 0                    ; Status
2578 .sip:           dd 0                    ; Source IP
2579 .dip:           dd 0                    ; Destination (our) IP
2580 .rport:         dw 0                    ; Remote port
2581 .lport:         dw 0                    ; Local port
2582 .buffersize:    dw 0                    ; Max packet size
2583 .buffer:        dw 0, 0                 ; seg:off of buffer
2584
2585 ;
2586 ; Misc initialized (data) variables
2587 ;
2588                 alignb 4, db 0
2589 BaseStack       dd StackBuf             ; ESP of base stack
2590                 dw 0                    ; SS of base stack
2591 NextSocket      dw 49152                ; Counter for allocating socket numbers
2592 KeepPXE         db 0                    ; Should PXE be kept around?
2593
2594 ;
2595 ; TFTP commands
2596 ;
2597 tftp_tail       db 'octet', 0                           ; Octet mode
2598 tsize_str       db 'tsize' ,0                           ; Request size
2599 tsize_len       equ ($-tsize_str)
2600                 db '0', 0
2601 blksize_str     db 'blksize', 0                         ; Request large blocks
2602 blksize_len     equ ($-blksize_str)
2603                 asciidec TFTP_LARGEBLK
2604                 db 0
2605 tftp_tail_len   equ ($-tftp_tail)
2606
2607                 alignb 2, db 0
2608 ;
2609 ; Options negotiation parsing table (string pointer, string len, offset
2610 ; into socket structure)
2611 ;
2612 tftp_opt_table:
2613                 dw tsize_str, tsize_len, tftp_filesize
2614                 dw blksize_str, blksize_len, tftp_blksize
2615 tftp_opts       equ ($-tftp_opt_table)/6
2616
2617 ;
2618 ; Error packet to return on options negotiation error
2619 ;
2620 tftp_opt_err    dw TFTP_ERROR                           ; ERROR packet
2621                 dw TFTP_EOPTNEG                         ; ERROR 8: bad options
2622                 db 'tsize option required', 0           ; Error message
2623 tftp_opt_err_len equ ($-tftp_opt_err)
2624
2625                 alignb 4, db 0
2626 ack_packet_buf: dw TFTP_ACK, 0                          ; TFTP ACK packet
2627
2628 ;
2629 ; IP information (initialized to "unknown" values)
2630 MyIP            dd 0                    ; My IP address
2631 ServerIP        dd 0                    ; IP address of boot server
2632 Netmask         dd 0                    ; Netmask of this subnet
2633 Gateway         dd 0                    ; Default router
2634 ServerPort      dw TFTP_PORT            ; TFTP server port
2635
2636 ;
2637 ; Variables that are uninitialized in SYSLINUX but initialized here
2638 ;
2639                 alignb 4, db 0
2640 BufSafe         dw trackbufsize/TFTP_BLOCKSIZE  ; Clusters we can load into trackbuf
2641 BufSafeBytes    dw trackbufsize         ; = how many bytes?
2642 %ifndef DEPEND
2643 %if ( trackbufsize % TFTP_BLOCKSIZE ) != 0
2644 %error trackbufsize must be a multiple of TFTP_BLOCKSIZE
2645 %endif
2646 %endif