Real-mode code might set the direction flag, which would cause carnage.
[people/xl0/gpxe.git] / src / arch / i386 / transitions / librm.S
1 /*
2  * librm: a library for interfacing to real-mode code
3  *
4  * Michael Brown <mbrown@fensystems.co.uk>
5  *
6  */
7
8 /* Drag in local definitions */
9 #include "librm.h"
10
11 /* For switches to/from protected mode */
12 #define CR0_PE 1
13
14 /* Size of various C data structures */
15 #define SIZEOF_I386_SEG_REGS    12
16 #define SIZEOF_I386_REGS        32
17 #define SIZEOF_REAL_MODE_REGS   ( SIZEOF_I386_SEG_REGS + SIZEOF_I386_REGS )
18 #define SIZEOF_I386_FLAGS       4
19 #define SIZEOF_I386_ALL_REGS    ( SIZEOF_REAL_MODE_REGS + SIZEOF_I386_FLAGS )
20         
21         .arch i386
22         .section ".text16", "ax", @progbits
23         .section ".text16.data", "aw", @progbits
24         .section ".data16", "aw", @progbits
25
26 /****************************************************************************
27  * Global descriptor table
28  *
29  * Call init_librm to set up the GDT before attempting to use any
30  * protected-mode code.
31  *
32  * Define FLATTEN_REAL_MODE if you want to use so-called "flat real
33  * mode" with 4GB limits instead.
34  *
35  * NOTE: This must be located before prot_to_real, otherwise gas
36  * throws a "can't handle non absolute segment in `ljmp'" error due to
37  * not knowing the value of REAL_CS when the ljmp is encountered.
38  *
39  * Note also that putting ".word gdt_end - gdt - 1" directly into
40  * gdt_limit, rather than going via gdt_length, will also produce the
41  * "non absolute segment" error.  This is most probably a bug in gas.
42  ****************************************************************************
43  */
44         
45 #ifdef FLATTEN_REAL_MODE
46 #define RM_LIMIT_16_19__AVL__SIZE__GRANULARITY 0x8f
47 #else
48 #define RM_LIMIT_16_19__AVL__SIZE__GRANULARITY 0x00
49 #endif
50         .section ".data16"
51         .align 16
52 gdt:
53 gdt_limit:              .word gdt_length - 1
54 gdt_base:               .long 0
55                         .word 0 /* padding */
56
57         .org    gdt + VIRTUAL_CS, 0
58 virtual_cs:     /* 32 bit protected mode code segment, virtual addresses */
59         .word   0xffff, 0
60         .byte   0, 0x9f, 0xcf, 0
61
62         .org    gdt + VIRTUAL_DS, 0
63 virtual_ds:     /* 32 bit protected mode data segment, virtual addresses */
64         .word   0xffff, 0
65         .byte   0, 0x93, 0xcf, 0
66         
67         .org    gdt + PHYSICAL_CS, 0
68 physical_cs:    /* 32 bit protected mode code segment, physical addresses */
69         .word   0xffff, 0
70         .byte   0, 0x9f, 0xcf, 0
71
72         .org    gdt + PHYSICAL_DS, 0
73 physical_ds:    /* 32 bit protected mode data segment, physical addresses */
74         .word   0xffff, 0
75         .byte   0, 0x93, 0xcf, 0        
76
77         .org    gdt + REAL_CS, 0
78 real_cs:        /* 16 bit real mode code segment */
79         .word   0xffff, 0
80         .byte   0, 0x9b, RM_LIMIT_16_19__AVL__SIZE__GRANULARITY, 0
81
82         .org    gdt + REAL_DS   
83 real_ds:        /* 16 bit real mode data segment */
84         .word   0xffff, 0
85         .byte   0, 0x93, RM_LIMIT_16_19__AVL__SIZE__GRANULARITY, 0
86         
87 gdt_end:
88         .equ    gdt_length, gdt_end - gdt
89
90 /****************************************************************************
91  * init_librm (real-mode far call, 16-bit real-mode far return address)
92  *
93  * Initialise the GDT ready for transitions to protected mode.
94  *
95  * Parameters:
96  *   %cs : .text16 segment
97  *   %ds : .data16 segment
98  *   %edi : Physical base of protected-mode code (virt_offset)
99  ****************************************************************************
100  */
101         .section ".text16"
102         .code16
103         .globl init_librm
104 init_librm:
105         /* Preserve registers */
106         pushl   %eax
107         pushl   %ebx
108
109         /* Store _virt_offset and set up virtual_cs and virtual_ds segments */
110         movl    %edi, %eax
111         movw    $virtual_cs, %bx
112         call    set_seg_base
113         movw    $virtual_ds, %bx
114         call    set_seg_base    
115         movl    %edi, _virt_offset
116
117         /* Negate virt_offset */
118         negl    %edi
119                 
120         /* Store rm_cs and _text16, set up real_cs segment */
121         xorl    %eax, %eax
122         movw    %cs, %ax
123         movw    %ax, rm_cs
124         shll    $4, %eax
125         movw    $real_cs, %bx
126         call    set_seg_base
127         addr32 leal     (%eax, %edi), %ebx
128         movl    %ebx, _text16
129
130         /* Store rm_ds and _data16, set up real_ds segment and set GDT base */
131         xorl    %eax, %eax
132         movw    %ds, %ax
133         movw    %ax, %cs:rm_ds
134         shll    $4, %eax
135         movw    $real_ds, %bx
136         call    set_seg_base
137         addr32 leal     (%eax, %edi), %ebx
138         movl    %ebx, _data16
139         addl    $gdt, %eax
140         movl    %eax, gdt_base
141                 
142         /* Restore registers */
143         negl    %edi
144         popl    %ebx
145         popl    %eax
146         lret
147
148         .section ".text16"
149         .code16
150 set_seg_base:
151 1:      movw    %ax, 2(%bx)
152         rorl    $16, %eax
153         movb    %al, 4(%bx)
154         movb    %ah, 7(%bx)
155         roll    $16, %eax
156         ret
157         
158 /****************************************************************************
159  * real_to_prot (real-mode near call, 32-bit virtual return address)
160  *
161  * Switch from 16-bit real-mode to 32-bit protected mode with virtual
162  * addresses.  The real-mode %ss:sp is stored in rm_ss and rm_sp, and
163  * the protected-mode %esp is restored from the saved pm_esp.
164  * Interrupts are disabled.  All other registers may be destroyed.
165  *
166  * The return address for this function should be a 32-bit virtual
167  * address.
168  *
169  * Parameters: 
170  *   %ecx : number of bytes to move from RM stack to PM stack
171  *
172  ****************************************************************************
173  */
174         .section ".text16"
175         .code16
176 real_to_prot:
177         /* Make sure we have our data segment available */
178         movw    %cs:rm_ds, %ax
179         movw    %ax, %ds
180         
181         /* Add _virt_offset, _text16 and _data16 to stack to be
182          * copied, and also copy the return address.
183          */
184         pushl   _virt_offset
185         pushl   _text16
186         pushl   _data16
187         addw    $16, %cx /* %ecx must be less than 64kB anyway */
188         
189         /* Real-mode %ss:%sp => %bp:%esi */
190         movw    %ss, %bp
191         movzwl  %sp, %esi
192
193         /* Switch to protected mode */
194         cli
195         data32 lgdt     gdt
196         movl    %cr0, %eax
197         orb     $CR0_PE, %al
198         movl    %eax, %cr0
199         data32 ljmp     $VIRTUAL_CS, $1f
200         .section ".text"
201         .code32
202 1:
203         /* Set up protected-mode data segments */
204         movw    $VIRTUAL_DS, %ax
205         movw    %ax, %ds
206         movw    %ax, %es
207         movw    %ax, %fs
208         movw    %ax, %gs
209
210         /* Move data from RM stack to PM stack and set up PM stack */
211         movl    pm_esp, %esp
212         subl    %ecx, %esp
213         movl    %esp, %edi
214         rep ss movsb
215         movw    %ax, %ss
216
217         /* Record real-mode %ss:sp (after removal of data) */
218         movw    %bp, rm_ss
219         movw    %si, rm_sp
220
221         /* Publish virt_offset, text16 and data16 for PM code to use */
222         popl    data16
223         popl    text16
224         popl    virt_offset
225
226         /* Return to virtual address */
227         ret
228
229 /****************************************************************************
230  * prot_to_real (protected-mode near call, 32-bit real-mode return address)
231  *
232  * Switch from 32-bit protected mode with virtual addresses to 16-bit
233  * real mode.  The protected-mode %esp is stored in pm_esp and the
234  * real-mode %ss:sp is restored from the saved rm_ss and rm_sp.  The
235  * high word of the real-mode %esp is set to zero.  All real-mode data
236  * segment registers are loaded from the saved rm_ds.  Interrupts are
237  * *not* enabled, since we want to be able to use prot_to_real in an
238  * ISR.  All other registers may be destroyed.
239  *
240  * The return address for this function should be a 32-bit (sic)
241  * real-mode offset within .code16.
242  *
243  * Parameters: 
244  *   %ecx : number of bytes to move from PM stack to RM stack
245  *
246  ****************************************************************************
247  */
248         .section ".text"
249         .code32
250 prot_to_real:
251         /* Add return address to data to be moved to RM stack */
252         addl    $4, %ecx
253         
254         /* Real-mode %ss:sp => %ebp:edx */
255         movzwl  rm_ss, %ebp
256         movzwl  rm_sp, %edx
257         subl    %ecx, %edx
258         
259         /* Move data from PM stack to RM stack */
260         movl    %ebp, %eax
261         shll    $4, %eax
262         leal    (%eax,%edx), %edi
263         subl    virt_offset, %edi
264         movl    %esp, %esi
265         rep movsb
266         
267         /* Record protected-mode %esp (after removal of data) */
268         movl    %esi, pm_esp
269
270         /* Load real-mode segment limits */
271         movw    $REAL_DS, %ax
272         movw    %ax, %ds
273         movw    %ax, %es
274         movw    %ax, %fs
275         movw    %ax, %gs
276         movw    %ax, %ss
277         ljmp    $REAL_CS, $1f
278         .section ".text16"
279         .code16
280 1:
281         /* Switch to real mode */
282         movl    %cr0, %eax
283         andb    $0!CR0_PE, %al
284         movl    %eax, %cr0
285         ljmp    *p2r_jump_vector
286 p2r_jump_target:
287
288         /* Set up real-mode stack */
289         movw    %bp, %ss
290         movl    %edx, %esp
291         
292         /* Set up real-mode data segments */
293         movw    %cs:rm_ds, %ax
294         movw    %ax, %ds
295         movw    %ax, %es
296         movw    %ax, %fs
297         movw    %ax, %gs
298
299         /* Return to real-mode address */
300         data32 ret
301
302
303         /* Real-mode code and data segments.  Assigned by the call to
304          * init_librm.  rm_cs doubles as the segment part of the jump
305          * vector used by prot_to_real.  rm_ds is located in .text16
306          * rather than .data16 because code needs to be able to locate
307          * the data segment.
308          */
309         .section ".data16"
310 p2r_jump_vector:
311         .word   p2r_jump_target
312         .globl rm_cs
313 rm_cs:  .word 0
314         .globl rm_ds
315         .section ".text16.data"
316 rm_ds:  .word 0
317         
318 /****************************************************************************
319  * prot_call (real-mode far call, 16-bit real-mode far return address)
320  *
321  * Call a specific C function in the protected-mode code.  The
322  * prototype of the C function must be
323  *   void function ( struct i386_all_regs *ix86 ); 
324  * ix86 will point to a struct containing the real-mode registers
325  * at entry to prot_call.  
326  *
327  * All registers will be preserved across prot_call(), unless the C
328  * function explicitly overwrites values in ix86.  Interrupt status
329  * and GDT will also be preserved.  Gate A20 will be enabled.
330  *
331  * Note that prot_call() does not rely on the real-mode stack
332  * remaining intact in order to return, since everything relevant is
333  * copied to the protected-mode stack for the duration of the call.
334  * In particular, this means that a real-mode prefix can make a call
335  * to main() which will return correctly even if the prefix's stack
336  * gets vapourised during the Etherboot run.  (The prefix cannot rely
337  * on anything else on the stack being preserved, so should move any
338  * critical data to registers before calling main()).
339  *
340  * Parameters:
341  *   function : virtual address of protected-mode function to call
342  *
343  * Example usage:
344  *      pushl   $pxe_api_call
345  *      call    prot_call
346  *      addw    $4, %sp
347  * to call in to the C function
348  *      void pxe_api_call ( struct i386_all_regs *ix86 );
349  ****************************************************************************
350  */
351
352 #define PC_OFFSET_GDT ( 0 )
353 #define PC_OFFSET_IX86 ( PC_OFFSET_GDT + 8 /* pad to 8 to keep alignment */ )
354 #define PC_OFFSET_RETADDR ( PC_OFFSET_IX86 + SIZEOF_I386_ALL_REGS )
355 #define PC_OFFSET_FUNCTION ( PC_OFFSET_RETADDR + 4 )
356 #define PC_OFFSET_END ( PC_OFFSET_FUNCTION + 4 )
357
358         .section ".text16"
359         .code16
360         .globl prot_call
361 prot_call:
362         /* Preserve registers, flags and GDT on external RM stack */
363         pushfl
364         pushal
365         pushw   %gs
366         pushw   %fs
367         pushw   %es
368         pushw   %ds
369         pushw   %ss
370         pushw   %cs
371         subw    $8, %sp
372         movw    %sp, %bp
373         sgdt    (%bp)
374
375         /* For sanity's sake, clear the direction flag as soon as possible */
376         cld
377
378         /* Switch to protected mode and move register dump to PM stack */
379         movl    $PC_OFFSET_END, %ecx
380         pushl   $1f
381         jmp     real_to_prot
382         .section ".text"
383         .code32
384 1:
385         /* Set up environment expected by C code */
386         call    gateA20_set
387
388         /* Call function */
389         leal    PC_OFFSET_IX86(%esp), %eax
390         pushl   %eax
391         call    *(PC_OFFSET_FUNCTION+4)(%esp)
392         popl    %eax /* discard */
393
394         /* Switch to real mode and move register dump back to RM stack */
395         movl    $PC_OFFSET_END, %ecx
396         pushl   $1f
397         jmp     prot_to_real
398         .section ".text16"
399         .code16
400 1:      
401         /* Reload GDT, restore registers and flags and return.  Note
402          * that %esp is restored manually, since popal discards it.
403          */
404         movw    %sp, %bp
405         lgdt    (%bp)
406         addw    $12, %sp /* also skip %cs and %ss */
407         popw    %ds
408         popw    %es
409         popw    %fs
410         popw    %gs
411         popal
412         addr32 movl -20(%esp), %esp /* -20(%sp) is not a valid 80386
413                                      * expression.  -20(%esp) is safe
414                                      * because prot_to_real zeroes the
415                                      * high word of %esp, and interrupts
416                                      * are still disabled at this point. */
417         popfl
418         lret
419
420 /****************************************************************************
421  * real_call (protected-mode near call, 32-bit virtual return address)
422  *
423  * Call a real-mode function from protected-mode code.
424  *
425  * The non-segment register values will be passed directly to the
426  * real-mode code.  The segment registers will be set as per
427  * prot_to_real.  The non-segment register values set by the real-mode
428  * function will be passed back to the protected-mode caller.  A
429  * result of this is that this routine cannot be called directly from
430  * C code, since it clobbers registers that the C ABI expects the
431  * callee to preserve.  Gate A20 will *not* be automatically
432  * re-enabled.  Since we always run from an even megabyte of memory,
433  * we are guaranteed to return successfully to the protected-mode
434  * code, which should then call gateA20_set() if it suspects that gate
435  * A20 may have been disabled.  Note that enabling gate A20 is a
436  * potentially slow operation that may also cause keyboard input to be
437  * lost; this is why it is not done automatically.
438  *
439  * librm.h defines a convenient macro REAL_CODE() for using real_call.
440  * See librm.h and realmode.h for details and examples.
441  *
442  * Parameters:
443  *   (32-bit) near pointer to real-mode function to call
444  *
445  * Returns: none
446  ****************************************************************************
447  */
448
449 #define RC_OFFSET_PRESERVE_REGS ( 0 )
450 #define RC_OFFSET_RETADDR ( RC_OFFSET_PRESERVE_REGS + SIZEOF_I386_REGS )
451 #define RC_OFFSET_FUNCTION ( RC_OFFSET_RETADDR + 4 )
452 #define RC_OFFSET_END ( RC_OFFSET_FUNCTION + 4 )
453
454         .section ".text"
455         .code32
456         .globl real_call
457 real_call:
458         /* Create register dump and function pointer copy on PM stack */
459         pushal
460         pushl   RC_OFFSET_FUNCTION(%esp)
461
462         /* Switch to real mode and move register dump to RM stack  */
463         movl    $( RC_OFFSET_RETADDR + 4 /* function pointer copy */ ), %ecx
464         pushl   $1f
465         jmp     prot_to_real
466         .section ".text16"
467         .code16
468 1:
469         /* Call real-mode function */
470         popl    rc_function
471         popal
472         call    *rc_function
473         pushal
474
475         /* For sanity's sake, clear the direction flag as soon as possible */
476         cld
477
478         /* Switch to protected mode and move register dump back to PM stack */
479         movl    $RC_OFFSET_RETADDR, %ecx
480         pushl   $1f
481         jmp     real_to_prot
482         .section ".text"
483         .code32
484 1:
485         /* Restore registers and return */
486         popal
487         ret
488
489
490         /* Function vector, used because "call xx(%sp)" is not a valid
491          * 16-bit expression.
492          */
493         .section ".data16"
494 rc_function:    .word 0, 0
495         
496 /****************************************************************************
497  * Stored real-mode and protected-mode stack pointers
498  *
499  * The real-mode stack pointer is stored here whenever real_to_prot
500  * is called and restored whenever prot_to_real is called.  The
501  * converse happens for the protected-mode stack pointer.
502  *
503  * Despite initial appearances this scheme is, in fact re-entrant,
504  * because program flow dictates that we always return via the point
505  * we left by.  For example:
506  *    PXE API call entry
507  *  1   real => prot
508  *        ...
509  *        Print a text string
510  *          ...
511  *  2       prot => real
512  *            INT 10
513  *  3       real => prot
514  *          ...
515  *        ...
516  *  4   prot => real
517  *    PXE API call exit
518  *
519  * At point 1, the RM mode stack value, say RPXE, is stored in
520  * rm_ss,sp.  We want this value to still be present in rm_ss,sp when
521  * we reach point 4.
522  *
523  * At point 2, the RM stack value is restored from RPXE.  At point 3,
524  * the RM stack value is again stored in rm_ss,sp.  This *does*
525  * overwrite the RPXE that we have stored there, but it's the same
526  * value, since the code between points 2 and 3 has managed to return
527  * to us.
528  ****************************************************************************
529  */
530         .section ".data"
531         .globl rm_sp
532 rm_sp:  .word 0
533         .globl rm_ss
534 rm_ss:  .word 0
535         .globl pm_esp
536 pm_esp: .long _estack
537
538 /****************************************************************************
539  * Virtual address offsets
540  *
541  * These are used by the protected-mode code to map between virtual
542  * and physical addresses, and to access variables in the .text16 or
543  * .data16 segments.
544  ****************************************************************************
545  */
546         /* Internal copies, created by init_librm (which runs in real mode) */
547         .section ".data16"
548 _virt_offset:   .long 0
549 _text16:        .long 0
550 _data16:        .long 0
551
552         /* Externally-visible copies, created by real_to_prot */
553         .section ".data"
554         .globl virt_offset
555 virt_offset:    .long 0 
556         .globl text16
557 text16:         .long 0
558         .globl data16
559 data16:         .long 0