src/util/symcheck.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use warnings;
   5
   6 use constant WARNING_SIZE => 512;
   7
   8 my $symtab = {};
   9
  10 # Scan output of "objdump -w -t bin/blib.a" and build up symbol table
  11 #
  12 my $object;
  13 while ( <> ) {
  14   chomp;
  15   if ( /^In archive/ ) {
  16     # Do nothing
  17   } elsif ( /^$/ ) {
  18     # Do nothing
  19   } elsif ( /^(\S+\.o):\s+file format/ ) {
  20     $object = $1;
  21   } elsif ( /^SYMBOL TABLE:/ ) {
  22     # Do nothing
  23   } elsif ( /^([0-9a-fA-F]+)\s(l|g|\s)......\s(\S+)\s+([0-9a-fA-F]+)\s+(\S+)$/ ) {
  24     my $value = $1;
  25     my $scope = $2;
  26     my $section = $3;
  27     my $size = $4;
  28     my $symbol = $5;
  29     $symtab->{$object}->{$symbol} = {
  30       global    => ( $scope ne "l" ),
  31       section   => ( $section eq "*UND*" ? undef : $section ),
  32       value     => ( $value ? hex ( $value ) : 0 ),
  33       size      => ( $size ? hex ( $size ) : 0 ),
  34     };
  35   } else {
  36     die "Unrecognized line \"$_\"";
  37   }
  38 }
  39
  40 # Add symbols that we know will be generated or required by the linker
  41 #
  42 foreach my $object ( keys %$symtab ) {
  43   my $obj_symbol = "obj_$object";
  44   $obj_symbol =~ s/\.o$//;
  45   $obj_symbol =~ s/\W/_/g;
  46   $symtab->{LINKER}->{$obj_symbol} = {
  47     global      => 1,
  48     section     => undef,
  49     value       => 0,
  50     size        => 0,
  51   };
  52 }
  53 foreach my $link_sym qw ( __prefix _prefix _prefix_load_offset
  54                           _prefix_size _prefix_progbits_size _prefix_size_pgh
  55                           __text16 _text16 _text16_load_offset
  56                           _text16_size _text16_progbits_size _text16_size_pgh
  57                           __data16 _data16 _data16_load_offset
  58                           _data16_size _data16_progbits_size _data16_size_pgh
  59                           __text _text __data _data _textdata_load_offset
  60                           _textdata_size _textdata_progbits_size
  61                           __rodata __bss _end
  62                           _payload_offset _max_align
  63                           _load_size _load_size_pgh _load_size_sect
  64                           pci_vendor_id pci_device_id ) {
  65   $symtab->{LINKER}->{$link_sym} = {
  66     global      => 1,
  67     section     => '*ABS*',
  68     value       => 0,
  69     size        => 0,
  70   };
  71 }
  72
  73 # Build up requires, provides and shares symbol tables for global
  74 # symbols
  75 #
  76 my $globals = {};
  77 while ( ( my $object, my $symbols ) = each %$symtab ) {
  78   while ( ( my $symbol, my $info ) = each %$symbols ) {
  79     if ( $info->{global} ) {
  80       my $category;
  81       if ( ! defined $info->{section} ) {
  82         $category = "requires";
  83       } elsif ( $info->{section} eq "*COM*" ) {
  84         $category = "shares";
  85       } else {
  86         $category = "provides";
  87       }
  88       $globals->{$symbol}->{$category}->{$object} = $info->{section};
  89     }
  90   }
  91 }
  92
  93 # Check for multiply defined, never-defined and unused global symbols
  94 #
  95 my $problems = {};
  96 while ( ( my $symbol, my $info ) = each %$globals ) {
  97   my @provides = keys %{$info->{provides}};
  98   my @requires = keys %{$info->{requires}};
  99   my @shares = keys %{$info->{shares}};
 100
 101   if ( ( @requires > 0 ) && ( @provides == 0 ) && ( @shares == 0 ) ) {
 102     # No object provides this symbol, but some objects require it.
 103     $problems->{$_}->{nonexistent}->{$symbol} = 1 foreach @requires;
 104   }
 105
 106   if ( ( @requires == 0 ) && ( @provides > 0 ) ) {
 107     # No object requires this symbol, but some objects provide it.
 108     foreach my $provide ( @provides ) {
 109       if ( $provide eq "LINKER" ) {
 110         # Linker-provided symbols are exempt from this check.
 111       } elsif ( $info->{provides}->{$provide} =~ /^\.tbl\./ ) {
 112         # Linker tables are exempt from this check.
 113       } else {
 114         $problems->{$provide}->{unused}->{$symbol} = 1;
 115       }
 116     }
 117   }
 118
 119   if ( ( @shares > 0 ) && ( @provides > 0 ) ) {
 120     # A shared symbol is being initialised by an object
 121     $problems->{$_}->{shared}->{$symbol} = 1 foreach @provides;
 122   }
 123
 124   if ( @provides > 1 ) {
 125     # A non-shared symbol is defined in multiple objects
 126     $problems->{$_}->{multiples}->{$symbol} = 1 foreach @provides;
 127   }
 128 }
 129
 130 # Check for excessively large local symbols.  Text and rodata symbols
 131 # are exempt from this check
 132 #
 133 while ( ( my $object, my $symbols ) = each %$symtab ) {
 134   while ( ( my $symbol, my $info ) = each %$symbols ) {
 135     if ( ( ! $info->{global} ) &&
 136          ( ( defined $info->{section} ) &&
 137            ! ( $info->{section} =~ /^(\.text|\.rodata)/ ) ) &&
 138          ( $info->{size} >= WARNING_SIZE ) ) {
 139       $problems->{$object}->{large}->{$symbol} = 1;
 140     }
 141   }
 142 }
 143
 144 # Print out error messages
 145 #
 146 my $errors = 0;
 147 my $warnings = 0;
 148 foreach my $object ( sort keys %$problems ) {
 149   my @nonexistent = sort keys %{$problems->{$object}->{nonexistent}};
 150   my @multiples = sort keys %{$problems->{$object}->{multiples}};
 151   my @unused = sort keys %{$problems->{$object}->{unused}};
 152   my @shared = sort keys %{$problems->{$object}->{shared}};
 153   my @large = sort keys %{$problems->{$object}->{large}};
 154
 155   print "WARN $object provides unused symbol $_\n" foreach @unused;
 156   $warnings += @unused;
 157   print "WARN $object has large static symbol $_\n" foreach @large;
 158   $warnings += @large;
 159   print "ERR  $object requires non-existent symbol $_\n" foreach @nonexistent;
 160   $errors += @nonexistent;
 161   foreach my $symbol ( @multiples ) {
 162     my @other_objects = sort grep { $_ ne $object }
 163                         keys %{$globals->{$symbol}->{provides}};
 164     print "ERR  $object provides symbol $symbol"
 165         ." (also provided by @other_objects)\n";
 166   }
 167   $errors += @multiples;
 168   print "ERR  $object misuses shared symbol $_\n" foreach @shared;
 169 }
 170
 171 print "$errors error(s), $warnings warning(s)\n";
 172 exit ( $errors ? 1 : 0 );