204894ef84fbfe680a0c37d99a89552d9b1fb98c
[people/mcb30/gpxe.git] / src / arch / i386 / interface / pxe / pxe_entry.S
1 /*
2  * Copyright (C) 2006 Michael Brown <mbrown@fensystems.co.uk>.
3  *
4  * This program is free software; you can redistribute it and/or
5  * modify it under the terms of the GNU General Public License as
6  * published by the Free Software Foundation; either version 2 of the
7  * License, or any later version.
8  *
9  * This program is distributed in the hope that it will be useful, but
10  * WITHOUT ANY WARRANTY; without even the implied warranty of
11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12  * General Public License for more details.
13  *
14  * You should have received a copy of the GNU General Public License
15  * along with this program; if not, write to the Free Software
16  * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
17  *
18  */
19
20         .arch i386
21         .section ".text16", "awx", @progbits
22         .section ".text16.data", "aw", @progbits
23         .section ".data16", "aw", @progbits
24
25 /****************************************************************************
26  * !PXE structure
27  ****************************************************************************
28  */
29         .section ".text16.data"
30         .globl ppxe
31         .align 16
32 ppxe:
33         .ascii "!PXE"                   /* Signature */
34         .byte pxe_length                /* StructLength */
35         .byte 0                         /* StructCksum */
36         .byte 0                         /* StructRev */
37         .byte 0                         /* reserved_1 */
38         .word 0, 0                      /* UNDIROMID */
39         .word 0, 0                      /* BaseROMID */
40         .word pxe_entry_sp, 0           /* EntryPointSP */
41         .word pxe_entry_esp, 0          /* EntryPointESP */
42         .word -1, -1                    /* StatusCallout */
43         .byte 0                         /* reserved_2 */
44         .byte SegDescCnt                /* SegDescCnt */
45         .word 0                         /* FirstSelector */
46 pxe_segments:
47         .word 0, 0, 0, _data16_size     /* Stack */
48         .word 0, 0, 0, _data16_size     /* UNDIData */
49         .word 0, 0, 0, _text16_size     /* UNDICode */
50         .word 0, 0, 0, _text16_size     /* UNDICodeWrite */
51         .word 0, 0, 0, 0                /* BC_Data */
52         .word 0, 0, 0, 0                /* BC_Code */
53         .word 0, 0, 0, 0                /* BC_CodeWrite */
54         .equ    SegDescCnt, ( ( . - pxe_segments ) / 8 )
55         .equ    pxe_length, . - ppxe
56         .size   ppxe, . - ppxe
57
58 /****************************************************************************
59  * PXENV+ structure
60  ****************************************************************************
61  */
62         .section ".text16.data"
63         .globl pxenv
64         .align 16
65 pxenv:
66         .ascii "PXENV+"                 /* Signature */
67         .word 0x0201                    /* Version */
68         .byte pxenv_length              /* Length */
69         .byte 0                         /* Checksum */
70         .word pxenv_entry, 0            /* RMEntry */
71         .long 0                         /* PMEntry */
72         .word 0                         /* PMSelector */
73         .word 0                         /* StackSeg */
74         .word _data16_size              /* StackSize */
75         .word 0                         /* BC_CodeSeg */
76         .word 0                         /* BC_CodeSize */
77         .word 0                         /* BC_DataSeg */
78         .word 0                         /* BC_DataSize */
79         .word 0                         /* UNDIDataSeg */
80         .word _data16_size              /* UNDIDataSize */
81         .word 0                         /* UNDICodeSeg */
82         .word _text16_size              /* UNDICodeSize */
83         .word ppxe, 0                   /* PXEPtr */
84         .equ    pxenv_length, . - pxenv
85         .size   pxenv, . - pxenv
86  
87 /****************************************************************************
88  * pxenv_entry (16-bit far call)
89  *
90  * PXE API call PXENV+ entry point
91  *
92  * Parameters:
93  *   %es:di : Far pointer to PXE parameter structure
94  *   %bx : PXE API call
95  * Returns:
96  *   %ax : PXE exit status
97  * Corrupts:
98  *   none
99  ****************************************************************************
100  */
101         .section ".text16"
102         .code16
103 pxenv_entry:
104         pushl   $pxe_api_call
105         pushw   %cs
106         call    prot_call
107         addl    $4, %esp
108         lret
109         .size   pxenv_entry, . - pxenv_entry
110
111 /****************************************************************************
112  * pxe_entry
113  *
114  * PXE API call !PXE entry point
115  *
116  * Parameters:
117  *   stack : Far pointer to PXE parameter structure
118  *   stack : PXE API call
119  * Returns:
120  *   %ax : PXE exit status
121  * Corrupts:
122  *   none
123  ****************************************************************************
124  */
125         .section ".text16"
126         .code16
127 pxe_entry:
128 pxe_entry_sp:
129         /* Preserve original %esp */
130         pushl   %esp
131         /* Zero high word of %esp to allow use of common code */
132         movzwl  %sp, %esp
133         jmp     pxe_entry_common
134 pxe_entry_esp:
135         /* Preserve %esp to match behaviour of pxe_entry_sp */
136         pushl   %esp
137 pxe_entry_common:
138         /* Save PXENV+ API call registers */
139         pushw   %es
140         pushw   %di
141         pushw   %bx
142         /* Load !PXE parameters from stack into PXENV+ registers */
143         addr32 movw     18(%esp), %bx
144         movw    %bx, %es
145         addr32 movw     16(%esp), %di
146         addr32 movw     14(%esp), %bx
147         /* Make call as for PXENV+ */
148         pushw   %cs
149         call    pxenv_entry
150         /* Restore PXENV+ registers */
151         popw    %bx
152         popw    %di
153         popw    %es
154         /* Restore original %esp and return */
155         popl    %esp
156         lret
157         .size   pxe_entry, . - pxe_entry
158
159 /****************************************************************************
160  * pxe_int_1a
161  *
162  * PXE INT 1A handler
163  *
164  * Parameters:
165  *   %ax : 0x5650
166  * Returns:
167  *   %ax : 0x564e
168  *   %es:bx : Far pointer to the PXENV+ structure
169  *   CF cleared
170  * Corrupts:
171  *   none
172  ****************************************************************************
173  */
174         .section ".text16"
175         .code16
176         .globl  pxe_int_1a
177 pxe_int_1a:
178         pushfw
179         cmpw    $0x5650, %ax
180         jne     1f
181         /* INT 1A,5650 - PXE installation check */
182         pushw   %cs
183         popw    %es
184         movw    $pxenv, %bx
185         movw    $0x564e, %ax
186         popfw
187         clc
188         lret    $2
189 1:      /* INT 1A,other - pass through */
190         popfw
191         ljmp    *%cs:pxe_int_1a_vector
192
193         .section ".text16.data"
194         .globl  pxe_int_1a_vector
195 pxe_int_1a_vector:      .long 0