src/util/symcheck.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use warnings;
   5
   6 use constant WARNING_SIZE => 2048;
   7
   8 my $symtab = {};
   9
  10 # Scan output of "nm -o -S bin/blib.a" and build up symbol table
  11 #
  12 while ( <> ) {
  13   chomp;
  14   ( my $object, undef, my $value, undef, my $size, my $type, my $symbol )
  15       = /^.*?:(.*?\.o):((\S+)(\s+(\S+))?)?\s+(\S)\s+(\S+)$/;
  16   $symtab->{$object}->{$symbol} = {
  17     global      => ( $type eq uc $type ),
  18     type        => ( $type ),
  19     value       => ( $value ? hex ( $value ) : 0 ),
  20     size        => ( $size ? hex ( $size ) : 0 ),
  21   };
  22 }
  23
  24 # Add symbols that we know will be generated or required by the linker
  25 #
  26 foreach my $object ( keys %$symtab ) {
  27   my $obj_symbol = "obj_$object";
  28   $obj_symbol =~ s/\.o$//;
  29   $obj_symbol =~ s/\W/_/g;
  30   $symtab->{LINKER}->{$obj_symbol} = {
  31     global      => 1,
  32     type        => 'U',
  33     value       => 0,
  34     size        => 0,
  35   };
  36 }
  37 foreach my $link_sym qw ( _prefix _eprefix _decompress _edecompress _text
  38                           _etext _data _edata _bss _ebss _end ) {
  39   $symtab->{LINKER}->{$link_sym} = {
  40     global      => 1,
  41     type        => 'A',
  42     value       => 0,
  43     size        => 0,
  44   };
  45 }
  46
  47 # Build up requires and provides tables for global symbols
  48 my $globals = {};
  49 while ( ( my $object, my $symbols ) = each %$symtab ) {
  50   while ( ( my $symbol, my $info ) = each %$symbols ) {
  51     if ( $info->{global} ) {
  52       my $category = ( ( $info->{type} eq 'U' ? "requires" : "provides" ) );
  53       $globals->{$symbol}->{$category}->{$object} = 1;
  54     }
  55   }
  56 }
  57
  58 # Check for multiply defined, never-defined and unused global symbols
  59 #
  60 my $problems = {};
  61 while ( ( my $symbol, my $info ) = each %$globals ) {
  62   my @provides = keys %{$info->{provides}};
  63   my @requires = keys %{$info->{requires}};
  64
  65   if ( @provides == 0 ) {
  66     # No object provides this symbol
  67     $problems->{$_}->{nonexistent}->{$symbol} = 1 foreach @requires;
  68   } elsif ( @provides > 1 ) {
  69     # Symbol defined in multiple objects
  70     $problems->{$_}->{multiples}->{$symbol} = 1 foreach @provides;
  71   }
  72   if ( @requires == 0 ) {
  73     # Symbol not required
  74     $problems->{$_}->{unused}->{$symbol} = 1 foreach @provides;
  75   }
  76 }
  77
  78 # Print out error messages
  79 #
  80 my $errors = 0;
  81 my $warnings = 0;
  82 foreach my $object ( sort keys %$problems ) {
  83   my @nonexistent = sort keys %{$problems->{$object}->{nonexistent}};
  84   my @multiples = sort keys %{$problems->{$object}->{multiples}};
  85   my @unused = sort keys %{$problems->{$object}->{unused}};
  86
  87   print "WARN $object provides unused symbol $_\n" foreach @unused;
  88   $warnings += @unused;
  89   print "ERR  $object requires non-existent symbol $_\n" foreach @nonexistent;
  90   $errors += @nonexistent;
  91   foreach my $symbol ( @multiples ) {
  92     my @other_objects = sort grep { $_ ne $object }
  93                         keys %{$globals->{$symbol}->{provides}};
  94     print "ERR  $object provides symbol $symbol"
  95         ." (also provided by @other_objects)\n";
  96   }
  97   $errors += @multiples;
  98 }
  99
 100 print "$errors error(s), $warnings warning(s)\n";
 101 exit ( $errors ? 1 : 0 );