src/util/symcheck.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use warnings;
   5
   6 my $symbols = {};
   7
   8 # Scan output of "nm -o -g bin/blib.a" and build up symbol cross-ref table
   9 #
  10 while ( <> ) {
  11   chomp;
  12   ( my $object, my $type, my $symbol ) = /^.*?:(.*?\.o):.*?\s(\S)\s(.*)$/;
  13   my $category = $type eq 'U' ? "requires" : "provides";
  14   $symbols->{$symbol}->{$category}->{$object} = 1;
  15 }
  16
  17 # Add symbols that we know will be generated or required by the linker
  18 #
  19 while ( ( my $symbol, my $info ) = each %$symbols ) {
  20   $info->{requires}->{LINKER} = 1 if $symbol =~ /^obj_/;
  21 }
  22 $symbols->{$_}->{provides}->{LINKER} = 1
  23     foreach qw ( _prefix _eprefix _decompress _edecompress _text
  24                  _etext _data _edata _bss _ebss _end );
  25
  26 # Check for multiply defined, never-defined and unused symbols
  27 #
  28 my $problems = {};
  29 while ( ( my $symbol, my $info ) = each %$symbols ) {
  30   my @provides = keys %{$info->{provides}};
  31   my @requires = keys %{$info->{requires}};
  32
  33   if ( @provides == 0 ) {
  34     # No object provides this symbol
  35     $problems->{$_}->{nonexistent}->{$symbol} = 1 foreach @requires;
  36   } elsif ( @provides > 1 ) {
  37     # Symbol defined in multiple objects
  38     $problems->{$_}->{multiples}->{$symbol} = 1 foreach @provides;
  39   }
  40   if ( @requires == 0 ) {
  41     # Symbol not required
  42     $problems->{$_}->{unused}->{$symbol} = 1 foreach @provides;
  43   }
  44 }
  45
  46 # Print out error messages
  47 #
  48 my $errors = 0;
  49 my $warnings = 0;
  50 foreach my $object ( sort keys %$problems ) {
  51   my @nonexistent = sort keys %{$problems->{$object}->{nonexistent}};
  52   my @multiples = sort keys %{$problems->{$object}->{multiples}};
  53   my @unused = sort keys %{$problems->{$object}->{unused}};
  54
  55   print "WARN $object provides unused symbol $_\n" foreach @unused;
  56   $warnings += @unused;
  57   print "ERR  $object requires non-existent symbol $_\n" foreach @nonexistent;
  58   $errors += @nonexistent;
  59   foreach my $symbol ( @multiples ) {
  60     my @other_objects = sort grep { $_ ne $object }
  61                         keys %{$symbols->{$symbol}->{provides}};
  62     print "ERR  $object provides symbol $symbol"
  63         ." (also provided by @other_objects)\n";
  64   }
  65   $errors += @multiples;
  66 }
  67
  68 print "$errors error(s), $warnings warning(s)\n";
  69 exit ( $errors ? 1 : 0 );