c55e581f824485aeab222a1695e8912ed578ccb0
[people/cooldavid/gpxe.git] / src / arch / i386 / interface / pxe / pxe_entry.S
1 /*
2  * Copyright (C) 2006 Michael Brown <mbrown@fensystems.co.uk>.
3  *
4  * This program is free software; you can redistribute it and/or
5  * modify it under the terms of the GNU General Public License as
6  * published by the Free Software Foundation; either version 2 of the
7  * License, or any later version.
8  *
9  * This program is distributed in the hope that it will be useful, but
10  * WITHOUT ANY WARRANTY; without even the implied warranty of
11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12  * General Public License for more details.
13  *
14  * You should have received a copy of the GNU General Public License
15  * along with this program; if not, write to the Free Software
16  * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
17  *
18  */
19
20         .arch i386
21         .section ".text16", "awx", @progbits
22         .section ".text16.data", "aw", @progbits
23         .section ".data16", "aw", @progbits
24
25 /****************************************************************************
26  * !PXE structure
27  ****************************************************************************
28  */
29         .section ".text16.data"
30         .globl ppxe
31         .align 16
32 ppxe:
33         .ascii "!PXE"                   /* Signature */
34         .byte pxe_length                /* StructLength */
35         .byte 0                         /* StructCksum */
36         .byte 0                         /* StructRev */
37         .byte 0                         /* reserved_1 */
38         .word undiheader, 0             /* UNDIROMID */
39         .word 0, 0                      /* BaseROMID */
40         .word pxe_entry_sp, 0           /* EntryPointSP */
41         .word pxe_entry_esp, 0          /* EntryPointESP */
42         .word -1, -1                    /* StatusCallout */
43         .byte 0                         /* reserved_2 */
44         .byte SegDescCnt                /* SegDescCnt */
45         .word 0                         /* FirstSelector */
46 pxe_segments:
47         .word 0, 0, 0, _data16_size     /* Stack */
48         .word 0, 0, 0, _data16_size     /* UNDIData */
49         .word 0, 0, 0, _text16_size     /* UNDICode */
50         .word 0, 0, 0, _text16_size     /* UNDICodeWrite */
51         .word 0, 0, 0, 0                /* BC_Data */
52         .word 0, 0, 0, 0                /* BC_Code */
53         .word 0, 0, 0, 0                /* BC_CodeWrite */
54         .equ    SegDescCnt, ( ( . - pxe_segments ) / 8 )
55         .equ    pxe_length, . - ppxe
56         .size   ppxe, . - ppxe
57
58         /* Define undiheader=0 as a weak symbol for non-ROM builds */
59         .section ".weak"
60         .weak   undiheader
61 undiheader:
62
63 /****************************************************************************
64  * PXENV+ structure
65  ****************************************************************************
66  */
67         .section ".text16.data"
68         .globl pxenv
69         .align 16
70 pxenv:
71         .ascii "PXENV+"                 /* Signature */
72         .word 0x0201                    /* Version */
73         .byte pxenv_length              /* Length */
74         .byte 0                         /* Checksum */
75         .word pxenv_entry, 0            /* RMEntry */
76         .long 0                         /* PMEntry */
77         .word 0                         /* PMSelector */
78         .word 0                         /* StackSeg */
79         .word _data16_size              /* StackSize */
80         .word 0                         /* BC_CodeSeg */
81         .word 0                         /* BC_CodeSize */
82         .word 0                         /* BC_DataSeg */
83         .word 0                         /* BC_DataSize */
84         .word 0                         /* UNDIDataSeg */
85         .word _data16_size              /* UNDIDataSize */
86         .word 0                         /* UNDICodeSeg */
87         .word _text16_size              /* UNDICodeSize */
88         .word ppxe, 0                   /* PXEPtr */
89         .equ    pxenv_length, . - pxenv
90         .size   pxenv, . - pxenv
91  
92 /****************************************************************************
93  * pxenv_entry (16-bit far call)
94  *
95  * PXE API call PXENV+ entry point
96  *
97  * Parameters:
98  *   %es:di : Far pointer to PXE parameter structure
99  *   %bx : PXE API call
100  * Returns:
101  *   %ax : PXE exit status
102  * Corrupts:
103  *   none
104  ****************************************************************************
105  */
106         .section ".text16"
107         .code16
108 pxenv_entry:
109         pushl   $pxe_api_call
110         pushw   %cs
111         call    prot_call
112         addl    $4, %esp
113         lret
114         .size   pxenv_entry, . - pxenv_entry
115
116 /****************************************************************************
117  * pxe_entry
118  *
119  * PXE API call !PXE entry point
120  *
121  * Parameters:
122  *   stack : Far pointer to PXE parameter structure
123  *   stack : PXE API call
124  * Returns:
125  *   %ax : PXE exit status
126  * Corrupts:
127  *   none
128  ****************************************************************************
129  */
130         .section ".text16"
131         .code16
132 pxe_entry:
133 pxe_entry_sp:
134         /* Preserve original %esp */
135         pushl   %esp
136         /* Zero high word of %esp to allow use of common code */
137         movzwl  %sp, %esp
138         jmp     pxe_entry_common
139 pxe_entry_esp:
140         /* Preserve %esp to match behaviour of pxe_entry_sp */
141         pushl   %esp
142 pxe_entry_common:
143         /* Save PXENV+ API call registers */
144         pushw   %es
145         pushw   %di
146         pushw   %bx
147         /* Load !PXE parameters from stack into PXENV+ registers */
148         addr32 movw     18(%esp), %bx
149         movw    %bx, %es
150         addr32 movw     16(%esp), %di
151         addr32 movw     14(%esp), %bx
152         /* Make call as for PXENV+ */
153         pushw   %cs
154         call    pxenv_entry
155         /* Restore PXENV+ registers */
156         popw    %bx
157         popw    %di
158         popw    %es
159         /* Restore original %esp and return */
160         popl    %esp
161         lret
162         .size   pxe_entry, . - pxe_entry
163
164 /****************************************************************************
165  * pxe_int_1a
166  *
167  * PXE INT 1A handler
168  *
169  * Parameters:
170  *   %ax : 0x5650
171  * Returns:
172  *   %ax : 0x564e
173  *   %es:bx : Far pointer to the PXENV+ structure
174  *   CF cleared
175  * Corrupts:
176  *   none
177  ****************************************************************************
178  */
179         .section ".text16"
180         .code16
181         .globl  pxe_int_1a
182 pxe_int_1a:
183         pushfw
184         cmpw    $0x5650, %ax
185         jne     1f
186         /* INT 1A,5650 - PXE installation check */
187         pushw   %cs
188         popw    %es
189         movw    $pxenv, %bx
190         movw    $0x564e, %ax
191         popfw
192         clc
193         lret    $2
194 1:      /* INT 1A,other - pass through */
195         popfw
196         ljmp    *%cs:pxe_int_1a_vector
197
198         .section ".text16.data"
199         .globl  pxe_int_1a_vector
200 pxe_int_1a_vector:      .long 0