[prefix] Use flat real mode for access to high memory
[people/cooldavid/gpxe.git] / src / arch / i386 / prefix / libprefix.S
1 /*
2  * Copyright (C) 2006 Michael Brown <mbrown@fensystems.co.uk>.
3  *
4  * This program is free software; you can redistribute it and/or
5  * modify it under the terms of the GNU General Public License as
6  * published by the Free Software Foundation; either version 2 of the
7  * License, or any later version.
8  *
9  * This program is distributed in the hope that it will be useful, but
10  * WITHOUT ANY WARRANTY; without even the implied warranty of
11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12  * General Public License for more details.
13  *
14  * You should have received a copy of the GNU General Public License
15  * along with this program; if not, write to the Free Software
16  * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
17  *
18  */
19
20 FILE_LICENCE ( GPL2_OR_LATER )
21
22         .arch i386
23
24 /**
25  * High memory temporary load address
26  *
27  * Temporary buffer into which to copy (or decompress) our runtime
28  * image, prior to calling get_memmap() and relocate().  We don't
29  * actually leave anything here once install() has returned.
30  *
31  * We use the start of an even megabyte so that we don't have to worry
32  * about the current state of the A20 line.
33  *
34  * We use 4MB rather than 2MB because some PXE stack / PMM BIOS
35  * combinations are known to place data required by other UNDI ROMs
36  * loader around the 2MB mark.
37  */
38         .globl  HIGHMEM_LOADPOINT
39         .equ    HIGHMEM_LOADPOINT, ( 4 << 20 )
40
41 /* Image compression enabled */
42 #define COMPRESS 1
43
44 #define CR0_PE 1
45
46 /*****************************************************************************
47  * Utility function: print character (with LF -> LF,CR translation)
48  *
49  * Parameters:
50  *   %al : character to print
51  *   %ds:di : output buffer (or %di=0 to print to console)
52  * Returns:
53  *   %ds:di : next character in output buffer (if applicable)
54  *****************************************************************************
55  */
56         .section ".prefix.lib", "awx", @progbits
57         .code16
58         .globl  print_character
59 print_character:
60         /* Preserve registers */
61         pushw   %ax
62         pushw   %bx
63         pushw   %bp
64         /* If %di is non-zero, write character to buffer and exit */
65         testw   %di, %di
66         jz      1f
67         movb    %al, %ds:(%di)
68         incw    %di
69         jmp     3f
70 1:      /* Print character */
71         movw    $0x0007, %bx            /* page 0, attribute 7 (normal) */
72         movb    $0x0e, %ah              /* write char, tty mode */
73         cmpb    $0x0a, %al              /* '\n'? */
74         jne     2f
75         int     $0x10
76         movb    $0x0d, %al
77 2:      int     $0x10
78         /* Restore registers and return */
79 3:      popw    %bp
80         popw    %bx
81         popw    %ax
82         ret
83         .size   print_character, . - print_character
84
85 /*****************************************************************************
86  * Utility function: print a NUL-terminated string
87  *
88  * Parameters:
89  *   %ds:si : string to print
90  *   %ds:di : output buffer (or %di=0 to print to console)
91  * Returns:
92  *   %ds:si : character after terminating NUL
93  *   %ds:di : next character in output buffer (if applicable)
94  *****************************************************************************
95  */
96         .section ".prefix.lib", "awx", @progbits
97         .code16
98         .globl  print_message
99 print_message:
100         /* Preserve registers */
101         pushw   %ax
102         /* Print string */
103 1:      lodsb
104         testb   %al, %al
105         je      2f
106         call    print_character
107         jmp     1b
108 2:      /* Restore registers and return */
109         popw    %ax
110         ret
111         .size   print_message, . - print_message
112
113 /*****************************************************************************
114  * Utility functions: print hex digit/byte/word/dword
115  *
116  * Parameters:
117  *   %al (low nibble) : digit to print
118  *   %al : byte to print
119  *   %ax : word to print
120  *   %eax : dword to print
121  *   %ds:di : output buffer (or %di=0 to print to console)
122  * Returns:
123  *   %ds:di : next character in output buffer (if applicable)
124  *****************************************************************************
125  */
126         .section ".prefix.lib", "awx", @progbits
127         .code16
128         .globl  print_hex_dword
129 print_hex_dword:
130         rorl    $16, %eax
131         call    print_hex_word
132         rorl    $16, %eax
133         /* Fall through */
134         .size   print_hex_dword, . - print_hex_dword
135         .globl  print_hex_word
136 print_hex_word:
137         xchgb   %al, %ah
138         call    print_hex_byte
139         xchgb   %al, %ah
140         /* Fall through */
141         .size   print_hex_word, . - print_hex_word
142         .globl  print_hex_byte
143 print_hex_byte:
144         rorb    $4, %al
145         call    print_hex_nibble
146         rorb    $4, %al
147         /* Fall through */
148         .size   print_hex_byte, . - print_hex_byte
149         .globl  print_hex_nibble
150 print_hex_nibble:
151         /* Preserve registers */
152         pushw   %ax
153         /* Print digit (technique by Norbert Juffa <norbert.juffa@amd.com> */
154         andb    $0x0f, %al
155         cmpb    $10, %al
156         sbbb    $0x69, %al
157         das
158         call    print_character
159         /* Restore registers and return */
160         popw    %ax
161         ret
162         .size   print_hex_nibble, . - print_hex_nibble
163
164 /*****************************************************************************
165  * Utility function: print PCI bus:dev.fn
166  *
167  * Parameters:
168  *   %ax : PCI bus:dev.fn to print
169  *   %ds:di : output buffer (or %di=0 to print to console)
170  * Returns:
171  *   %ds:di : next character in output buffer (if applicable)
172  *****************************************************************************
173  */
174         .section ".prefix.lib", "awx", @progbits
175         .code16
176         .globl  print_pci_busdevfn
177 print_pci_busdevfn:
178         /* Preserve registers */
179         pushw   %ax
180         /* Print bus */
181         xchgb   %al, %ah
182         call    print_hex_byte
183         /* Print ":" */
184         movb    $( ':' ), %al
185         call    print_character
186         /* Print device */
187         movb    %ah, %al
188         shrb    $3, %al
189         call    print_hex_byte
190         /* Print "." */
191         movb    $( '.' ), %al
192         call    print_character
193         /* Print function */
194         movb    %ah, %al
195         andb    $0x07, %al
196         call    print_hex_nibble
197         /* Restore registers and return */
198         popw    %ax
199         ret
200         .size   print_pci_busdevfn, . - print_pci_busdevfn
201
202 /*****************************************************************************
203  * Utility function: clear current line
204  *
205  * Parameters:
206  *   %ds:di : output buffer (or %di=0 to print to console)
207  * Returns:
208  *   %ds:di : next character in output buffer (if applicable)
209  *****************************************************************************
210  */
211         .section ".prefix.lib", "awx", @progbits
212         .code16
213         .globl  print_kill_line
214 print_kill_line:
215         /* Preserve registers */
216         pushw   %ax
217         pushw   %cx
218         /* Print CR */
219         movb    $( '\r' ), %al
220         call    print_character
221         /* Print 79 spaces */
222         movb    $( ' ' ), %al
223         movw    $79, %cx
224 1:      call    print_character
225         loop    1b
226         /* Print CR */
227         movb    $( '\r' ), %al
228         call    print_character
229         /* Restore registers and return */
230         popw    %cx
231         popw    %ax
232         ret
233         .size   print_kill_line, . - print_kill_line
234
235 /****************************************************************************
236  * flatten_real_mode
237  *
238  * Set up 4GB segment limits
239  *
240  * Parameters:
241  *   none
242  * Returns:
243  *   none
244  * Corrupts:
245  *   none
246  ****************************************************************************
247  */
248 #ifndef KEEP_IT_REAL
249
250         /* GDT for protected-mode calls */
251         .section ".prefix.lib", "awx", @progbits
252         .align 16
253 flatten_vars:
254 flatten_gdt:
255 flatten_gdt_limit:      .word flatten_gdt_length - 1
256 flatten_gdt_base:       .long 0
257                         .word 0 /* padding */
258 flatten_cs:     /* 16-bit protected-mode flat code segment */
259         .equ    FLAT_CS, flatten_cs - flatten_gdt
260         .word   0xffff, 0
261         .byte   0, 0x9b, 0x8f, 0
262 flatten_ss:     /* 16-bit protected-mode flat stack segment */
263         .equ    FLAT_SS, flatten_ss - flatten_gdt
264         .word   0xffff, 0
265         .byte   0, 0x93, 0x8f, 0
266 flatten_gdt_end:
267         .equ    flatten_gdt_length, . - flatten_gdt
268         .size   flatten_gdt, . - flatten_gdt
269
270         .section ".prefix.lib", "awx", @progbits
271         .align 16
272 flatten_saved_gdt:
273         .long   0, 0
274         .size   flatten_saved_gdt, . - flatten_saved_gdt
275
276         .equ    flatten_vars_size, . - flatten_vars
277 #define FLATTEN_VAR(x) ( -flatten_vars_size + ( (x) - flatten_vars ) )
278
279         .section ".prefix.lib", "awx", @progbits
280         .code16
281 flatten_real_mode:
282         /* Preserve registers and flags, allocate local variable block */
283         pushw   %bp
284         movw    %sp, %bp
285         subw    $flatten_vars_size, %sp
286         andw    $0xfff0, %sp
287         pushfl
288         pushl   %eax
289         pushl   %edi
290         pushw   %si
291         pushw   %cx
292         pushw   %gs
293         pushw   %fs
294         pushw   %es
295         pushw   %ds
296         pushw   %ss
297
298         /* Fill local variable block and preserve GDT */
299         pushw   %ss
300         popw    %es
301         movw    $flatten_vars, %si
302         leaw    FLATTEN_VAR(flatten_vars)(%bp), %di
303         movw    $flatten_vars_size, %cx
304         cs rep movsb
305         sgdt    FLATTEN_VAR(flatten_saved_gdt)(%bp)
306
307         /* Set up GDT bases */
308         xorl    %eax, %eax
309         movw    %ss, %ax
310         shll    $4, %eax
311         movzwl  %bp, %edi
312         addr32 leal FLATTEN_VAR(flatten_gdt)(%eax, %edi), %eax
313         movl    %eax, FLATTEN_VAR(flatten_gdt_base)(%bp)
314         movw    %cs, %ax
315         movw    $FLATTEN_VAR(flatten_cs), %di
316         call    set_seg_base
317         movw    %ss, %ax
318         movw    $FLATTEN_VAR(flatten_ss), %di
319         call    set_seg_base
320
321         /* Switch temporarily to protected mode and set segment registers */
322         pushw   %cs
323         pushw   $2f
324         cli
325         data32 lgdt FLATTEN_VAR(flatten_gdt)(%bp)
326         movl    %cr0, %eax
327         orb     $CR0_PE, %al
328         movl    %eax, %cr0
329         ljmp    $FLAT_CS, $1f
330 1:      movw    $FLAT_SS, %ax
331         movw    %ax, %ss
332         movw    %ax, %ds
333         movw    %ax, %es
334         movw    %ax, %fs
335         movw    %ax, %gs
336         movl    %cr0, %eax
337         andb    $0!CR0_PE, %al
338         movl    %eax, %cr0
339         lret
340 2:      /* lret will ljmp to here */
341
342         /* Restore GDT, registers and flags */
343         data32 lgdt FLATTEN_VAR(flatten_saved_gdt)(%bp)
344         popw    %ss
345         popw    %ds
346         popw    %es
347         popw    %fs
348         popw    %gs
349         popw    %cx
350         popw    %si
351         popl    %edi
352         popl    %eax
353         popfl
354         movw    %bp, %sp
355         popw    %bp
356         ret
357         .size flatten_real_mode, . - flatten_real_mode
358
359 set_seg_base:
360         rolw    $4, %ax
361         movw    %ax, 2(%bp,%di)
362         andw    $0xfff0, 2(%bp,%di)
363         movb    %al, 4(%bp,%di)
364         andb    $0x0f, 4(%bp,%di)
365         ret
366         .size set_seg_base, . - set_seg_base
367
368 #endif /* KEEP_IT_REAL */
369
370 /****************************************************************************
371  * copy_bytes
372  *
373  * Copy bytes
374  *
375  * Parameters:
376  *   %ds:esi : source address
377  *   %es:edi : destination address
378  *   %ecx : length
379  * Returns:
380  *   %ds:esi : next source address
381  *   %es:edi : next destination address
382  * Corrupts:
383  *   None
384  ****************************************************************************
385  */
386 #if ! COMPRESS
387         .section ".prefix.lib", "awx", @progbits
388         .code16
389 copy_bytes:
390         pushl %ecx
391         rep addr32 movsb
392         popl %ecx
393         ret
394         .size copy_bytes, . - copy_bytes
395 #endif /* COMPRESS */
396
397 /****************************************************************************
398  * install_block
399  *
400  * Install block to specified address
401  *
402  * Parameters:
403  *   %esi : source physical address (must be a multiple of 16)
404  *   %edi : destination physical address (must be a multiple of 16)
405  *   %ecx : length of (decompressed) data
406  *   %edx : total length of block (including any uninitialised data portion)
407  * Returns:
408  *   %esi : next source physical address (will be a multiple of 16)
409  * Corrupts:
410  *   none
411  ****************************************************************************
412  */
413         .section ".prefix.lib", "awx", @progbits
414         .code16
415 install_block:
416         /* Preserve registers */
417         pushw   %ds
418         pushw   %es
419         pushl   %ecx
420         pushl   %edi
421         
422         /* Convert %esi and %edi to %ds:esi and %es:edi */
423         shrl    $4, %esi
424         movw    %si, %ds
425         xorw    %si, %si
426         shll    $4, %esi
427         shrl    $4, %edi
428         movw    %di, %es
429         xorw    %di, %di
430         shll    $4, %edi
431
432 #if COMPRESS
433         /* Decompress source to destination */
434         call    decompress16
435 #else
436         /* Copy source to destination */
437         call    copy_bytes
438 #endif
439
440         /* Zero .bss portion */
441         negl    %ecx
442         addl    %edx, %ecx
443         pushw   %ax
444         xorw    %ax, %ax
445         rep addr32 stosb
446         popw    %ax
447
448         /* Round up %esi to start of next source block */
449         addl    $0xf, %esi
450         andl    $~0xf, %esi
451
452         /* Convert %ds:esi back to a physical address */
453         xorl    %ecx, %ecx
454         movw    %ds, %cx
455         shll    $4, %ecx
456         addl    %ecx, %esi
457
458         /* Restore registers and return */
459         popl    %edi
460         popl    %ecx
461         popw    %es
462         popw    %ds
463         ret
464         .size install_block, . - install_block
465
466 /****************************************************************************
467  * alloc_basemem
468  *
469  * Allocate space for .text16 and .data16 from top of base memory.
470  * Memory is allocated using the BIOS free base memory counter at
471  * 0x40:13.
472  *
473  * Parameters: 
474  *   none
475  * Returns:
476  *   %ax : .text16 segment address
477  *   %bx : .data16 segment address
478  * Corrupts:
479  *   none
480  ****************************************************************************
481  */
482         .section ".prefix.lib", "awx", @progbits
483         .code16
484         .globl  alloc_basemem
485 alloc_basemem:
486         /* Preserve registers */
487         pushw   %fs
488
489         /* FBMS => %ax as segment address */
490         pushw   $0x40
491         popw    %fs
492         movw    %fs:0x13, %ax
493         shlw    $6, %ax
494
495         /* Calculate .data16 segment address */
496         subw    $_data16_memsz_pgh, %ax
497         pushw   %ax
498
499         /* Calculate .text16 segment address */
500         subw    $_text16_memsz_pgh, %ax
501         pushw   %ax
502
503         /* Update FBMS */
504         shrw    $6, %ax
505         movw    %ax, %fs:0x13
506
507         /* Retrieve .text16 and .data16 segment addresses */
508         popw    %ax
509         popw    %bx
510
511         /* Restore registers and return */
512         popw    %fs
513         ret
514         .size alloc_basemem, . - alloc_basemem
515
516 /****************************************************************************
517  * free_basemem
518  *
519  * Free space allocated with alloc_basemem.
520  *
521  * Parameters:
522  *   %ax : .text16 segment address
523  *   %bx : .data16 segment address
524  * Returns:
525  *   %ax : 0 if successfully freed
526  * Corrupts:
527  *   none
528  ****************************************************************************
529  */
530         .section ".text16", "ax", @progbits
531         .code16
532         .globl  free_basemem
533 free_basemem:
534         /* Preserve registers */
535         pushw   %fs
536
537         /* Check FBMS counter */
538         pushw   %ax
539         shrw    $6, %ax
540         pushw   $0x40
541         popw    %fs
542         cmpw    %ax, %fs:0x13
543         popw    %ax
544         jne     1f
545
546         /* Check hooked interrupt count */
547         cmpw    $0, %cs:hooked_bios_interrupts
548         jne     1f
549
550         /* OK to free memory */
551         addw    $_text16_memsz_pgh, %ax
552         addw    $_data16_memsz_pgh, %ax
553         shrw    $6, %ax
554         movw    %ax, %fs:0x13
555         xorw    %ax, %ax
556
557 1:      /* Restore registers and return */
558         popw    %fs
559         ret
560         .size free_basemem, . - free_basemem
561
562         .section ".text16.data", "aw", @progbits
563         .globl  hooked_bios_interrupts
564 hooked_bios_interrupts:
565         .word   0
566         .size   hooked_bios_interrupts, . - hooked_bios_interrupts
567
568 /****************************************************************************
569  * install
570  *
571  * Install all text and data segments.
572  *
573  * Parameters:
574  *   none
575  * Returns:
576  *   %ax  : .text16 segment address
577  *   %bx  : .data16 segment address
578  * Corrupts:
579  *   none
580  ****************************************************************************
581  */
582         .section ".prefix.lib", "awx", @progbits
583         .code16
584         .globl install
585 install:
586         /* Preserve registers */
587         pushl   %esi
588         pushl   %edi
589         /* Allocate space for .text16 and .data16 */
590         call    alloc_basemem
591         /* Image source = %cs:0000 */
592         xorl    %esi, %esi
593         /* Image destination = HIGHMEM_LOADPOINT */
594         movl    $HIGHMEM_LOADPOINT, %edi
595         /* Install text and data segments */
596         call    install_prealloc
597         /* Restore registers and return */
598         popl    %edi
599         popl    %esi
600         ret
601         .size install, . - install
602
603 /****************************************************************************
604  * install_prealloc
605  *
606  * Install all text and data segments.
607  *
608  * Parameters:
609  *   %ax  : .text16 segment address
610  *   %bx  : .data16 segment address
611  *   %esi : Image source physical address (or zero for %cs:0000)
612  *   %edi : Decompression temporary area physical address
613  * Corrupts:
614  *   none
615  ****************************************************************************
616  */
617         .section ".prefix.lib", "awx", @progbits
618         .code16
619         .globl install_prealloc
620 install_prealloc:
621         /* Save registers */
622         pushal
623         pushw   %ds
624         pushw   %es
625
626         /* Sanity: clear the direction flag asap */
627         cld
628
629 #ifndef KEEP_IT_REAL
630         /* Flatten real mode */
631         call    flatten_real_mode
632 #endif
633
634         /* Calculate physical address of payload (i.e. first source) */
635         testl   %esi, %esi
636         jnz     1f
637         movw    %cs, %si
638         shll    $4, %esi
639 1:      addl    $_payload_lma, %esi
640
641         /* Install .text16 and .data16 */
642         pushl   %edi
643         movzwl  %ax, %edi
644         shll    $4, %edi
645         movl    $_text16_memsz, %ecx
646         movl    %ecx, %edx
647         call    install_block           /* .text16 */
648         movzwl  %bx, %edi
649         shll    $4, %edi
650         movl    $_data16_filesz, %ecx
651         movl    $_data16_memsz, %edx
652         call    install_block           /* .data16 */
653         popl    %edi
654
655         /* Set up %ds for access to .data16 */
656         movw    %bx, %ds
657
658 #ifdef KEEP_IT_REAL
659         /* Initialise libkir */
660         movw    %ax, (init_libkir_vector+2)
661         lcall   *init_libkir_vector
662 #else
663         /* Install .text and .data to temporary area in high memory,
664          * prior to reading the E820 memory map and relocating
665          * properly.
666          */
667         movl    $_textdata_filesz, %ecx
668         movl    $_textdata_memsz, %edx
669         call    install_block
670
671         /* Initialise librm at current location */
672         movw    %ax, (init_librm_vector+2)
673         lcall   *init_librm_vector
674
675         /* Call relocate() to determine target address for relocation.
676          * relocate() will return with %esi, %edi and %ecx set up
677          * ready for the copy to the new location.
678          */
679         movw    %ax, (prot_call_vector+2)
680         pushl   $relocate
681         lcall   *prot_call_vector
682         popl    %edx /* discard */
683
684         /* Copy code to new location */
685         pushl   %edi
686         xorw    %ax, %ax
687         movw    %ax, %es
688         es rep addr32 movsb
689         popl    %edi
690
691         /* Initialise librm at new location */
692         lcall   *init_librm_vector
693 #endif
694
695         /* Restore registers */
696         popw    %es
697         popw    %ds
698         popal
699         ret
700         .size install_prealloc, . - install_prealloc
701
702         /* Vectors for far calls to .text16 functions.  Must be in
703          * .data16, since .prefix may not be writable.
704          */
705         .section ".data16", "aw", @progbits
706 #ifdef KEEP_IT_REAL
707 init_libkir_vector:
708         .word init_libkir
709         .word 0
710         .size init_libkir_vector, . - init_libkir_vector
711 #else
712 init_librm_vector:
713         .word init_librm
714         .word 0
715         .size init_librm_vector, . - init_librm_vector
716 prot_call_vector:
717         .word prot_call
718         .word 0
719         .size prot_call_vector, . - prot_call_vector
720 #endif
721
722 /****************************************************************************
723  * uninstall
724  *
725  * Uninstall all text and data segments.
726  *
727  * Parameters:
728  *   %ax  : .text16 segment address
729  *   %bx  : .data16 segment address
730  * Returns:
731  *   none
732  * Corrupts:
733  *   none
734  ****************************************************************************
735  */
736         .section ".text16", "ax", @progbits
737         .code16
738         .globl uninstall
739 uninstall:
740         call    free_basemem
741         ret
742         .size uninstall, . - uninstall
743
744
745
746         /* File split information for the compressor */
747 #if COMPRESS
748         .section ".zinfo", "a", @progbits
749         .ascii  "COPY"
750         .long   _prefix_lma
751         .long   _prefix_filesz
752         .long   _max_align
753         .ascii  "PACK"
754         .long   _text16_lma
755         .long   _text16_filesz
756         .long   _max_align
757         .ascii  "PACK"
758         .long   _data16_lma
759         .long   _data16_filesz
760         .long   _max_align
761         .ascii  "PACK"
762         .long   _textdata_lma
763         .long   _textdata_filesz
764         .long   _max_align
765 #else /* COMPRESS */
766         .section ".zinfo", "a", @progbits
767         .ascii  "COPY"
768         .long   _prefix_lma
769         .long   _filesz
770         .long   _max_align
771 #endif /* COMPRESS */