src/arch/i386/interface/pxe/pxe_entry.S

   1 /*
   2  * Copyright (C) 2006 Michael Brown <mbrown@fensystems.co.uk>.
   3  *
   4  * This program is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU General Public License as
   6  * published by the Free Software Foundation; either version 2 of the
   7  * License, or any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program; if not, write to the Free Software
  16  * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17  *
  18  */
  19
  20         .arch i386
  21
  22 /****************************************************************************
  23  * !PXE structure
  24  ****************************************************************************
  25  */
  26         .section ".text16.data", "aw", @progbits
  27         .globl ppxe
  28         .align 16
  29 ppxe:
  30         .ascii "!PXE"                   /* Signature */
  31         .byte pxe_length                /* StructLength */
  32         .byte 0                         /* StructCksum */
  33         .byte 0                         /* StructRev */
  34         .byte 0                         /* reserved_1 */
  35         .word undiheader, 0             /* UNDIROMID */
  36         .word 0, 0                      /* BaseROMID */
  37         .word pxe_entry_sp, 0           /* EntryPointSP */
  38         .word pxe_entry_esp, 0          /* EntryPointESP */
  39         .word -1, -1                    /* StatusCallout */
  40         .byte 0                         /* reserved_2 */
  41         .byte SegDescCnt                /* SegDescCnt */
  42         .word 0                         /* FirstSelector */
  43 pxe_segments:
  44         .word 0, 0, 0, _data16_memsz    /* Stack */
  45         .word 0, 0, 0, _data16_memsz    /* UNDIData */
  46         .word 0, 0, 0, _text16_memsz    /* UNDICode */
  47         .word 0, 0, 0, _text16_memsz    /* UNDICodeWrite */
  48         .word 0, 0, 0, 0                /* BC_Data */
  49         .word 0, 0, 0, 0                /* BC_Code */
  50         .word 0, 0, 0, 0                /* BC_CodeWrite */
  51         .equ    SegDescCnt, ( ( . - pxe_segments ) / 8 )
  52         .equ    pxe_length, . - ppxe
  53         .size   ppxe, . - ppxe
  54
  55         /* Define undiheader=0 as a weak symbol for non-ROM builds */
  56         .section ".weak", "a", @nobits
  57         .weak   undiheader
  58 undiheader:
  59
  60 /****************************************************************************
  61  * PXENV+ structure
  62  ****************************************************************************
  63  */
  64         .section ".text16.data", "aw", @progbits
  65         .globl pxenv
  66         .align 16
  67 pxenv:
  68         .ascii "PXENV+"                 /* Signature */
  69         .word 0x0201                    /* Version */
  70         .byte pxenv_length              /* Length */
  71         .byte 0                         /* Checksum */
  72         .word pxenv_entry, 0            /* RMEntry */
  73         .long 0                         /* PMEntry */
  74         .word 0                         /* PMSelector */
  75         .word 0                         /* StackSeg */
  76         .word _data16_memsz             /* StackSize */
  77         .word 0                         /* BC_CodeSeg */
  78         .word 0                         /* BC_CodeSize */
  79         .word 0                         /* BC_DataSeg */
  80         .word 0                         /* BC_DataSize */
  81         .word 0                         /* UNDIDataSeg */
  82         .word _data16_memsz             /* UNDIDataSize */
  83         .word 0                         /* UNDICodeSeg */
  84         .word _text16_memsz             /* UNDICodeSize */
  85         .word ppxe, 0                   /* PXEPtr */
  86         .equ    pxenv_length, . - pxenv
  87         .size   pxenv, . - pxenv
  88
  89 /****************************************************************************
  90  * pxenv_entry (16-bit far call)
  91  *
  92  * PXE API call PXENV+ entry point
  93  *
  94  * Parameters:
  95  *   %es:di : Far pointer to PXE parameter structure
  96  *   %bx : PXE API call
  97  * Returns:
  98  *   %ax : PXE exit status
  99  * Corrupts:
 100  *   none
 101  ****************************************************************************
 102  */
 103         /* Wyse Streaming Manager server (WLDRM13.BIN) assumes that
 104          * the PXENV+ entry point is at UNDI_CS:0000; apparently,
 105          * somebody at Wyse has difficulty distinguishing between the
 106          * words "may" and "must"...
 107          */
 108         .section ".text16.null", "ax", @progbits
 109         .code16
 110 pxenv_null_entry:
 111         jmp     pxenv_entry
 112
 113         .section ".text16", "ax", @progbits
 114         .code16
 115 pxenv_entry:
 116         pushl   $pxe_api_call
 117         pushw   %cs
 118         call    prot_call
 119         addl    $4, %esp
 120         lret
 121         .size   pxenv_entry, . - pxenv_entry
 122
 123 /****************************************************************************
 124  * pxe_entry
 125  *
 126  * PXE API call !PXE entry point
 127  *
 128  * Parameters:
 129  *   stack : Far pointer to PXE parameter structure
 130  *   stack : PXE API call
 131  * Returns:
 132  *   %ax : PXE exit status
 133  * Corrupts:
 134  *   none
 135  ****************************************************************************
 136  */
 137         .section ".text16", "ax", @progbits
 138         .code16
 139 pxe_entry:
 140 pxe_entry_sp:
 141         /* Preserve original %esp */
 142         pushl   %esp
 143         /* Zero high word of %esp to allow use of common code */
 144         movzwl  %sp, %esp
 145         jmp     pxe_entry_common
 146 pxe_entry_esp:
 147         /* Preserve %esp to match behaviour of pxe_entry_sp */
 148         pushl   %esp
 149 pxe_entry_common:
 150         /* Save PXENV+ API call registers */
 151         pushw   %es
 152         pushw   %di
 153         pushw   %bx
 154         /* Load !PXE parameters from stack into PXENV+ registers */
 155         addr32 movw     18(%esp), %bx
 156         movw    %bx, %es
 157         addr32 movw     16(%esp), %di
 158         addr32 movw     14(%esp), %bx
 159         /* Make call as for PXENV+ */
 160         pushw   %cs
 161         call    pxenv_entry
 162         /* Restore PXENV+ registers */
 163         popw    %bx
 164         popw    %di
 165         popw    %es
 166         /* Restore original %esp and return */
 167         popl    %esp
 168         lret
 169         .size   pxe_entry, . - pxe_entry
 170
 171 /****************************************************************************
 172  * pxe_int_1a
 173  *
 174  * PXE INT 1A handler
 175  *
 176  * Parameters:
 177  *   %ax : 0x5650
 178  * Returns:
 179  *   %ax : 0x564e
 180  *   %es:bx : Far pointer to the PXENV+ structure
 181  *   CF cleared
 182  * Corrupts:
 183  *   none
 184  ****************************************************************************
 185  */
 186         .section ".text16", "ax", @progbits
 187         .code16
 188         .globl  pxe_int_1a
 189 pxe_int_1a:
 190         pushfw
 191         cmpw    $0x5650, %ax
 192         jne     1f
 193         /* INT 1A,5650 - PXE installation check */
 194         pushw   %cs
 195         popw    %es
 196         movw    $pxenv, %bx
 197         movw    $0x564e, %ax
 198         popfw
 199         clc
 200         lret    $2
 201 1:      /* INT 1A,other - pass through */
 202         popfw
 203         ljmp    *%cs:pxe_int_1a_vector
 204
 205         .section ".text16.data", "aw", @progbits
 206         .globl  pxe_int_1a_vector
 207 pxe_int_1a_vector:      .long 0