4a984a95684100d3f55ca6ce862f91f8f239dc59
[gpxe.git] / src / arch / i386 / scripts / i386.lds
1 /* -*- sh -*- */
2
3 /*
4  * Linker script for i386 images
5  *
6  */
7
8 OUTPUT_FORMAT ( "elf32-i386", "elf32-i386", "elf32-i386" )
9 OUTPUT_ARCH ( i386 )
10 ENTRY ( _entry )
11
12 SECTIONS {
13
14     /* All sections in the resulting file have consecutive load
15      * addresses, but may have individual link addresses depending on
16      * the memory model being used.
17      *
18      * The linker symbols {prefix,text}_link_addr, load_addr, and
19      * _max_align may be specified explicitly.  If not specified, they
20      * will default to:
21      *
22      *   _prefix_link_addr      = 0
23      *   _textdata_link_addr    = 0
24      *   _load_addr             = 0
25      *   _max_align             = 16
26      * 
27      * We guarantee alignment of virtual addresses to any alignment
28      * specified by the constituent object files (e.g. via
29      * __attribute__((aligned(x)))).  Load addresses are guaranteed
30      * only up to _max_align.  Provided that all loader and relocation
31      * code honours _max_align, this means that physical addresses are
32      * also guaranteed up to _max_align.
33      *
34      * Note that when using -DKEEP_IT_REAL, the UNDI segments are only
35      * guaranteed to be loaded on a paragraph boundary (i.e. 16-byte
36      * alignment).  Using _max_align>16 will therefore not guarantee
37      * >16-byte alignment of physical addresses when -DKEEP_IT_REAL is
38      * used (though virtual addresses will still be fully aligned).
39      *
40      */
41
42     /*
43      * The prefix
44      */
45
46     _prefix_link_addr = DEFINED ( _prefix_link_addr ) ? _prefix_link_addr : 0;
47     . = _prefix_link_addr;
48     _prefix = .;
49
50     .prefix : AT ( _prefix_load_offset + __prefix ) {
51         __prefix = .;
52         _entry = .;
53         *(.prefix)
54         *(.prefix.*)
55         _eprefix_progbits = .;
56     }
57     
58     _eprefix = .;
59
60     /*
61      * The 16-bit sections, if present
62      */
63
64     _text16_link_addr = 0;
65     . = _text16_link_addr;
66     _text16 = .;
67
68     .text16 : AT ( _text16_load_offset + __text16 ) {
69         __text16 = .;
70         *(.text16)
71         *(.text16.*)
72         _etext16_progbits = .;
73     } = 0x9090
74
75     _etext16 = .;
76
77     _data16_link_addr = 0;
78     . = _data16_link_addr;
79     _data16 = .;
80
81     .rodata16 : AT ( _data16_load_offset + __rodata16 ) {
82         __rodata16 = .;
83         *(.rodata16)
84         *(.rodata16.*)
85     }
86     .data16 : AT ( _data16_load_offset + __data16 ) {
87         __data16 = .;
88         *(.data16)
89         *(.data16.*)
90         _edata16_progbits = .;
91     }
92     .bss16 : AT ( _data16_load_offset + __bss16 ) {
93         __bss16 = .;
94         _bss16 = .;
95         *(.bss16)
96         *(.bss16.*)
97         _ebss16 = .;
98     }
99     .stack16 : AT ( _data16_load_offset + __stack16 ) {
100         __stack16 = .;
101         *(.stack16)
102         *(.stack16.*)
103     }
104
105     _edata16 = .;
106
107     /*
108      * The 32-bit sections
109      */
110
111     _textdata_link_addr = ( DEFINED ( _textdata_link_addr ) ?
112                             _textdata_link_addr : 0 );
113     . = _textdata_link_addr;
114     _textdata = .;
115
116     _text = .;
117
118     .text : AT ( _textdata_load_offset + __text ) {
119         __text = .;
120         *(.text)
121         *(.text.*)
122     } = 0x9090
123
124     _etext = .;
125
126     _data = .;
127
128     .rodata : AT ( _textdata_load_offset + __rodata ) {
129         __rodata = .;
130         *(.rodata)
131         *(.rodata.*)
132     }
133     .data : AT ( _textdata_load_offset + __data ) {
134         __data = .;
135         *(.data)
136         *(.data.*)
137         *(SORT(.tbl.*))         /* Various tables.  See include/tables.h */
138         _etextdata_progbits = .;
139     }
140     .bss : AT ( _textdata_load_offset + __bss ) {
141         __bss = .;
142         _bss = .;
143         *(.bss)
144         *(.bss.*)
145         *(COMMON)
146         _ebss = .;
147     }
148     .stack : AT ( _textdata_load_offset + __stack ) {
149         __stack = .;
150         *(.stack)
151         *(.stack.*)
152     }
153
154     _edata = .;
155
156     _etextdata = .;
157
158     _end = .;
159
160     /*
161      * Dispose of the comment and note sections to make the link map
162      * easier to read
163      */
164
165     /DISCARD/ : {
166         *(.comment)
167         *(.note)
168     }
169
170     /*
171      * Load address calculations.  The slightly obscure nature of the
172      * calculations is because ALIGN(x) can only operate on the
173      * location counter.
174      */
175
176     _max_align              = DEFINED ( _max_align ) ? _max_align : 16;
177     _load_addr              = DEFINED ( _load_addr ) ? _load_addr : 0;
178
179     .                       = _load_addr;
180
181     .                      -= _prefix_link_addr;
182     _prefix_load_offset     = ALIGN ( _max_align );
183     _prefix_load_addr       = _prefix_link_addr + _prefix_load_offset;
184     _prefix_size            = _eprefix - _prefix;
185     _prefix_progbits_size   = _eprefix_progbits - _prefix;
186     .                       = _prefix_load_addr + _prefix_progbits_size;
187
188     .                      -= _text16_link_addr;
189     _text16_load_offset     = ALIGN ( _max_align );
190     _text16_load_addr       = _text16_link_addr + _text16_load_offset;
191     _text16_size            = _etext16 - _text16;
192     _text16_progbits_size   = _etext16_progbits - _text16;
193     .                       = _text16_load_addr + _text16_progbits_size;
194
195     .                      -= _data16_link_addr;
196     _data16_load_offset     = ALIGN ( _max_align );
197     _data16_load_addr       = _data16_link_addr + _data16_load_offset;
198     _data16_size            = _edata16 - _data16;
199     _data16_progbits_size   = _edata16_progbits - _data16;
200     .                       = _data16_load_addr + _data16_progbits_size;
201
202     .                      -= _textdata_link_addr;
203     _textdata_load_offset   = ALIGN ( _max_align );
204     _textdata_load_addr     = _textdata_link_addr + _textdata_load_offset;
205     _textdata_size          = _etextdata - _textdata;
206     _textdata_progbits_size = _etextdata_progbits - _textdata;
207     .                       = _textdata_load_addr + _textdata_progbits_size;
208
209     .                       = ALIGN ( _max_align );
210
211     _load_size              = . - _load_addr;
212
213     /*
214      * Alignment checks.  ALIGN() can only operate on the location
215      * counter, so we set the location counter to each value we want
216      * to check.
217      */
218
219     . = _prefix_load_addr - _prefix_link_addr;
220     _assert = ASSERT ( ( . == ALIGN ( _max_align ) ),
221                        "_prefix is badly aligned" );
222
223     . = _text16_load_addr - _text16_link_addr;
224     _assert = ASSERT ( ( . == ALIGN ( _max_align ) ),
225                        "_text16 is badly aligned" );
226
227     . = _data16_load_addr - _data16_link_addr;
228     _assert = ASSERT ( ( . == ALIGN ( _max_align ) ),
229                        "_data16 is badly aligned" );
230
231     . = _textdata_load_addr - _textdata_link_addr;
232     _assert = ASSERT ( ( . == ALIGN ( _max_align ) ),
233                        "_text is badly aligned" );
234
235     /*
236      * Values calculated to save code from doing it
237      */
238     _load_size_pgh      = ( _load_size / 16 );
239     _rom_size           = ( ( _load_size + 511 ) / 512 );
240 }